wayland: Add make_modal protocol method

protocol/pantheon-desktop-shell-v1.xml

@@ -119,6 +119,14 @@
       </description>
     </request>
 
+    <request name="make_modal">
+      <description summary="requests to make a surface system modal">
+        This will block all user input outside the surface and most system shortcuts.
+      </description>
+
+      <arg name="dim" type="uint" summary="1 to dim, 0 to not dim"/>
+    </request>
+
     <request name="focus">
       <description summary="request keyboard focus">
         Request keyboard focus, taking it away from any other window.

protocol/pantheon-desktop-shell.vapi

@@ -57,6 +57,7 @@ namespace Pantheon.Desktop {
         public Destroy destroy;
         public SetKeepAbove set_keep_above;
         public MakeCentered make_centered;
+        public MakeModal make_modal;
         public Focus focus;
     }
 
@@ -79,5 +80,7 @@ namespace Pantheon.Desktop {
     [CCode (has_target = false, has_typedef = false)]
     public delegate void MakeCentered (Wl.Client client, Wl.Resource resource);
     [CCode (has_target = false, has_typedef = false)]
+    public delegate void MakeModal (Wl.Client client, Wl.Resource resource, uint dim);
+    [CCode (has_target = false, has_typedef = false)]
     public delegate void Destroy (Wl.Client client, Wl.Resource resource);
 }

src/InternalUtils.vala

@@ -336,5 +336,15 @@ namespace Gala {
                 return { 0, 0, (int) screen_width, (int) screen_height };
             }
         }
+
+        public static void clutter_actor_reparent (Clutter.Actor actor, Clutter.Actor new_parent) {
+            if (actor == new_parent)
+                return;
+
+            actor.ref ();
+            actor.get_parent ().remove_child (actor);
+            new_parent.add_child (actor);
+            actor.unref ();
+        }
     }
 }

src/PantheonShell.vala

@@ -68,6 +68,7 @@ namespace Gala {
             destroy_extended_behavior_surface,
             set_keep_above,
             make_centered,
+            make_modal,
             focus_extended_behavior,
         };
 
@@ -359,6 +360,23 @@ namespace Gala {
         ShellClientsManager.get_instance ().make_centered (window);
     }
 
+    internal static void make_modal (Wl.Client client, Wl.Resource resource, uint dim) {
+        unowned ExtendedBehaviorSurface? eb_surface = resource.get_user_data<ExtendedBehaviorSurface> ();
+        if (eb_surface.wayland_surface == null) {
+            warning ("Window tried to make modal but wayland surface is null.");
+            return;
+        }
+
+        Meta.Window? window;
+        eb_surface.wayland_surface.get ("window", out window, null);
+        if (window == null) {
+            warning ("Window tried to make modal but wayland surface had no associated window.");
+            return;
+        }
+
+        ShellClientsManager.get_instance ().make_modal (window, dim == 1);
+    }
+
     internal static void destroy_panel_surface (Wl.Client client, Wl.Resource resource) {
         resource.destroy ();
     }

src/ShellClients/ShellClientsManager.vala

@@ -8,7 +8,7 @@
 public class Gala.ShellClientsManager : Object {
     private static ShellClientsManager instance;
 
-    public static void init (WindowManager wm) {
+    public static void init (WindowManagerGala wm) {
         if (instance != null) {
             return;
         }
@@ -20,15 +20,15 @@ public class Gala.ShellClientsManager : Object {
         return instance;
     }
 
-    public WindowManager wm { get; construct; }
+    public WindowManagerGala wm { get; construct; }
 
     private NotificationsClient notifications_client;
     private ManagedClient[] protocol_clients = {};
 
     private GLib.HashTable<Meta.Window, PanelWindow> windows = new GLib.HashTable<Meta.Window, PanelWindow> (null, null);
     private GLib.HashTable<Meta.Window, CenteredWindow> centered_windows = new GLib.HashTable<Meta.Window, CenteredWindow> (null, null);
 
-    private ShellClientsManager (WindowManager wm) {
+    private ShellClientsManager (WindowManagerGala wm) {
         Object (wm: wm);
     }
 
@@ -193,6 +193,10 @@ public class Gala.ShellClientsManager : Object {
         window.unmanaging.connect_after (() => centered_windows.remove (window));
     }
 
+    public void make_modal (Meta.Window window, bool dim) {
+        wm.modal_actor.make_modal (window, dim);
+    }
+
     public bool is_positioned_window (Meta.Window window) {
         bool positioned = (window in centered_windows) || (window in windows);
         window.foreach_ancestor ((ancestor) => {

src/Widgets/ModalActor.vala

@@ -0,0 +1,77 @@
+/*
+ * Copyright 2024 elementary, Inc. (https://elementary.io)
+ * SPDX-License-Identifier: GPL-3.0-or-later
+ *
+ * Authored by: Leonhard Kargl <[email protected]>
+ */
+
+/**
+ * This class allows to make windows system modal i.e. dim
+ * the desktop behind them and only allow interaction with them.
+ * Not to be confused with WindowManager.push_modal which only
+ * works for our own Clutter.Actors.
+ */
+ public class Gala.ModalActor : Clutter.Actor {
+    public Meta.Display display { get; construct; }
+
+    private int modal_dialogs = 0;
+
+    public ModalActor (Meta.Display display) {
+        Object (display: display);
+    }
+
+    construct {
+        background_color = { 0, 0, 0, 200 };
+        x = 0;
+        y = 0;
+        visible = false;
+        reactive = true;
+
+        unowned var monitor_manager = display.get_context ().get_backend ().get_monitor_manager ();
+        monitor_manager.monitors_changed.connect (update_size);
+
+        update_size ();
+    }
+
+    private void update_size () {
+        int width, height;
+        display.get_size (out width, out height);
+
+        set_size (width, height);
+    }
+
+    public void make_modal (Meta.Window window, bool dim) {
+        modal_dialogs++;
+        window.unmanaged.connect (unmake_modal);
+
+        var actor = (Meta.WindowActor) window.get_compositor_private ();
+        InternalUtils.clutter_actor_reparent (actor, this);
+
+        if (dim) {
+            background_color = { 0, 0, 0, 200 };
+        } else {
+            background_color = { 0, 0, 0, 0 };
+        }
+
+        check_visible ();
+    }
+
+    public void unmake_modal (Meta.Window window) {
+        modal_dialogs--;
+        window.unmanaged.disconnect (unmake_modal);
+
+        check_visible ();
+    }
+
+    private void check_visible () {
+        visible = modal_dialogs > 0;
+
+        if (visible) {
+            get_parent ().set_child_above_sibling (this, null);
+        }
+    }
+
+    public bool is_modal () {
+        return modal_dialogs > 0;
+    }
+}

src/WindowManager.vala

@@ -49,6 +49,8 @@ namespace Gala {
          */
          public Gala.ActivatableComponent workspace_view { get; protected set; }
 
+        public ModalActor modal_actor { get; private set; }
+
         /**
          * {@inheritDoc}
          */
@@ -244,6 +246,9 @@ namespace Gala {
             stage.remove_child (feedback_group);
             ui_group.add_child (feedback_group);
 
+            modal_actor = new ModalActor (display);
+            ui_group.insert_child_above (modal_actor, null);
+
             FilterManager.init (this);
 
             /*keybindings*/
@@ -2338,6 +2343,10 @@ namespace Gala {
         }
 
         public override bool keybinding_filter (Meta.KeyBinding binding) {
+            if (modal_actor.is_modal ()) {
+                return true;
+            }
+
             if (!is_modal ())
                 return false;
 

src/meson.build

@@ -51,6 +51,7 @@ gala_bin_sources = files(
     'Widgets/DwellClickTimer.vala',
     'Widgets/IconGroup.vala',
     'Widgets/IconGroupContainer.vala',
+    'Widgets/ModalActor.vala',
     'Widgets/MonitorClone.vala',
     'Widgets/MultitaskingView.vala',
     'Widgets/PixelPicker.vala',