Added two extension methods for CMAbstractModel

src/Cormas-OpenMole-Tests/CMOpenMoleBridgeTest.class.st

@@ -29,8 +29,49 @@ CMOpenMoleBridgeTest >> testLastDataOfModel [
 	data := CMOpenMoleBridge lastDataOfModel: model.
 
 	expectedData := {
-		#numberOfAliveAgents -> model class defaultNumberOfAgents .
+		#numberOfAliveAgents -> model class defaultInitialNumberOfAgents .
 		#numberOfDeadAgents -> 0 } asDictionary.
 
 	self assert: data equals: expectedData.
 ]
+
+{ #category : #tests }
+CMOpenMoleBridgeTest >> testLoadInputParametersFromJson [
+
+	| contents file |
+
+	contents := '{ 
+		"numberOfRows": 10,
+		"numberOfColumns": 13,
+		"initialNumberOfAgents": 2
+	}'.
+
+	file := FileSystem memory / 'input.json'.
+	file writeStreamDo: [ :stream | stream nextPutAll: contents ].
+
+	model loadInputParametersFromJson: file.
+
+	self assert: model numberOfRows equals: 10.
+	self assert: model numberOfColumns equals: 13.
+	self assert: model initialNumberOfAgents equals: 2.
+]
+
+{ #category : #tests }
+CMOpenMoleBridgeTest >> testSaveProbesToJson [
+
+	| expectedDictionary actualDictionary file |
+
+	expectedDictionary := {
+		'numberOfAliveAgents' -> 5 .
+		'numberOfDeadAgents' -> 0
+	} asDictionary.
+
+	file := FileSystem memory / 'output.json'.
+
+	model initializeSimulation.
+	model saveProbesToJson: file.
+
+	actualDictionary := STONJSON fromString: file contents.
+
+	self assert: actualDictionary equals: expectedDictionary.
+]

src/Cormas-OpenMole/CMAbstractModel.extension.st

@@ -1,7 +1,40 @@
 Extension { #name : #CMAbstractModel }
 
+{ #category : #'*Cormas-OpenMole' }
+CMAbstractModel >> loadInputParametersFromJson: aFileReference [
+
+	| jsonString parameters selector |
+
+	jsonString := aFileReference
+		readStreamDo: [ :stream | stream contents ].
+
+	parameters := STONJSON fromString: jsonString.
+
+	parameters keysAndValuesDo: [ :parameterName :value |
+		selector := (parameterName, ':') asSymbol.
+		self perform: selector with: value ].
+
+
+]
+
 { #category : #'*Cormas-OpenMole' }
 CMAbstractModel >> runOpenMoleSimulation [
 
 	"TODO"
 ]
+
+{ #category : #'*Cormas-OpenMole' }
+CMAbstractModel >> saveProbesToJson: aFileReference [
+
+	| probesDictionary jsonString |
+
+	probesDictionary := (self class probes collect: [ :selector |
+		selector asString -> (self perform: selector)
+	]) asDictionary.
+
+	jsonString := STONJSON toString: probesDictionary.
+
+	aFileReference writeStreamDo: [ :stream | 
+		stream nextPutAll: jsonString ].
+
+]