-
Notifications
You must be signed in to change notification settings - Fork 0
/
gen-janet-pkgs-page.janet
177 lines (154 loc) · 5.23 KB
/
gen-janet-pkgs-page.janet
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
#!/usr/bin/env janet
# Copyright 2021--2022 John Gabriele.
# See LICENSE.txt file for license.
# This script downloads the pkgs.janet file from the
# Janet package repository (git repo), then downloads
# descriptions of all the packages listed therein,
# creating an html page containing all package names
# with their descriptions.
#
# Usage:
#
# gen-janet-pkgs-page.janet > index.html
(import janet-html)
# For getting the 'declare-project out of a project.janet file.
# bakpakin wrote, then added this for the next Janet release.
# Need it here until the next Janet release.
(defn parse-all
``Parse a string and return all parsed values as a tuple. For complex
parsing, such as for a repl with error handling, use the `parser` api.``
[str]
(let [p (parser/new)
ret @[]]
(parser/consume p str)
(parser/eof p)
(while (parser/has-more p)
(array/push ret (parser/produce p)))
(if (= :error (parser/status p))
(error (parser/error p))
ret)))
(defn shell-out
``The `cmd` arg should be a list of strings, just like
what you pass to `os/spawn`.``
[cmd]
(let [x (os/spawn cmd :p {:out :pipe})
s (:read (x :out) :all)]
(:wait x)
s))
# For each project we'll need to get its project.janet file
# to extract name, author, description, url, and license.
#
# If it's at sourcehut, given a git repo url, get the raw
# project.janet like so:
#
# https://git.sr.ht/~bakpakin/temple
# https://git.sr.ht/~bakpakin/temple/blob/master/project.janet
#
# If it's a github project, then that's:
#
# https://github.com/andrewchambers/janet-big.git
# https://raw.githubusercontent.com/andrewchambers/janet-big/master/project.janet
#
# If it's at gitlab:
#
# https://gitlab.com/louis.jackman/janet-hypertext.git
# https://gitlab.com/louis.jackman/janet-hypertext/-/raw/master/project.janet
(defn sourcehut-raw-project-file-url
[git-url]
(string git-url "/blob/master/project.janet"))
(defn github-raw-project-file-url
[git-url]
(let [prefix "https://raw.githubusercontent.com/"
suffix "/master/project.janet"
mid (string/slice git-url 19 -5)]
(string prefix mid suffix)))
(defn gitlab-raw-project-file-url
[git-url]
(let [suffix "/-/raw/master/project.janet"
prefix (string/slice git-url 0 -5)]
(string prefix suffix)))
(defn get-and-parse-janet-project-file
``Returns the defproject struct for a given project name.
Maintains a "./project-janet-files" directory where it caches
downloaded "project.janet" files.``
[name url]
(def dirnm "project-janet-files")
(when (not (os/stat dirnm))
(eprint dirnm " directory not found. Making it...")
(os/mkdir dirnm))
(os/cd dirnm)
(def proj-fnm (string name ".project.janet"))
(when (not (os/stat proj-fnm))
(eprint "Can't find " proj-fnm ". Fetching it...")
(cond
(string/has-prefix? "https://git.sr.ht/" url)
(shell-out ["wget" (sourcehut-raw-project-file-url url)])
(string/has-prefix? "https://github.com/" url)
(shell-out ["wget" (github-raw-project-file-url url)])
(string/has-prefix? "https://gitlab.com/" url)
(shell-out ["wget" (gitlab-raw-project-file-url url)])
(do (eprint name ". Not sourcehut, github, nor gitlab. Bailing out.")
(os/exit 1)))
(os/rename "project.janet" proj-fnm))
(def prj-struct
(struct ;(drop 1
(find |(match $ ['declare-project & rest] rest)
(parse-all (slurp proj-fnm))))))
(os/cd "..")
prj-struct)
(defn make-table-row
``Given a project-name/git-url pair, returns a data structure
representing one html table row, suitable for use by `janet-html/html`.``
[itm]
#(pp itm) # debug
(let [name (string (get itm 0))
git-url (get itm 1)
proj (get-and-parse-janet-project-file name git-url)]
[:tr [:td [:a {:href (proj :url)} name]]
[:td (proj :description)]]))
(def css-content ``
h1, h2, th {
font-family: sans-serif;
}
table, th, td {
border: 1px solid #ccc;
border-collapse: collapse;
padding: 10px;
}
thead {
background-color: #09a5b8;
color: #fff;
}
tbody tr:nth-child(odd) {
background-color: #fff;
}
tbody tr:nth-child(even) {
background-color: #eee;
}
``)
#------------------------------------------------------------------
(defn main
[&]
(when (not (os/stat "pkgs.janet"))
(shell-out
["wget"
"https://raw.githubusercontent.com/janet-lang/pkgs/master/pkgs.janet"]))
# Array of pairs of package name symbol and git repo url.
(def pkgs (pairs (eval (get (parse (slurp "pkgs.janet"))
2))))
(sort-by |(get $ 0) pkgs)
#(pp pkgs) # debug
(def out-html (janet-html/html
[:html
[:head
[:title "Janet Package Directory"]
[:style css-content]]
[:body
[:h1 "Janet Package Directory"]
[:p "Generated from the "
[:a {:href "https://github.com/janet-lang/pkgs"}
"Janet package listing"] "."]
[:table
[:thead [:tr [:th "Package"] [:th "Description"]]]
(map make-table-row pkgs)]]]))
(print out-html))