-
Notifications
You must be signed in to change notification settings - Fork 45
/
biblioteq.macos.pro
107 lines (94 loc) · 3.94 KB
/
biblioteq.macos.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
include(biblioteq-source.pro)
dmg.commands = make install && \
hdiutil create BiblioteQ.d.dmg -srcfolder BiblioteQ.d
purge.commands = find . -name '*~*' -exec rm -f {} \;
CONFIG += qt release warn_on
exists(/opt/homebrew/Cellar/libpq/16.4/lib/libpq.dylib) {
DEFINES += BIBLIOTEQ_MACOS_LIBPQ_PATH="'\"/opt/homebrew/Cellar/libpq/16.4/lib/libpq.dylib\"'"
} else {
warning("/opt/homebrew/Cellar/libpq/16.4/lib/libpq.dylib does not exist.")
}
exists(/usr/local/Cellar/libpq/16.4/lib/libpq.dylib) {
DEFINES += BIBLIOTEQ_MACOS_LIBPQ_PATH="'\"/usr/local/Cellar/libpq/16.4/lib/libpq.dylib\"'"
} else {
warning("/usr/local/Cellar/libpq/16.4/lib/libpq.dylib does not exist.")
}
DEFINES += QT_DEPRECATED_WARNINGS
LANGUAGE = C++
QT += gui network printsupport sql widgets
QT -= webkit
QMAKE_CLEAN += BiblioteQ
QMAKE_CXXFLAGS_RELEASE += -Wall \
-Wcast-align \
-Wcast-qual \
-Wextra \
-Wformat=2 \
-Wno-deprecated-declarations \
-Woverloaded-virtual \
-Wpointer-arith \
-Wstack-protector \
-fPIE \
-fstack-protector-all \
-funroll-loops \
-fwrapv \
-pedantic \
-std=c++17
QMAKE_DISTCLEAN += -r \
.qmake.cache \
.qmake.stash \
BiblioteQ \
BiblioteQ.d \
Temporary
QMAKE_EXTRA_TARGETS = dmg purge
QMAKE_MACOSX_DEPLOYMENT_TARGET = 12.0
ICON = Icons/book.icns
INCLUDEPATH += Source
LIBS += -framework AppKit -framework Cocoa
OBJECTIVE_HEADERS += Source/CocoaInitializer.h
OBJECTIVE_SOURCES += Source/CocoaInitializer.mm
PROJECTNAME = BiblioteQ
TARGET = BiblioteQ
TEMPLATE = app
biblioteq.files = BiblioteQ.app/*
biblioteq.path = BiblioteQ.d/BiblioteQ.app
conf.files = biblioteq.conf
conf.path = BiblioteQ.d
data.files = Data/*
data.path = BiblioteQ.d/Data
doc1.files = Documentation/*.html Documentation/*.pdf \
Documentation/*.txt Documentation/TO-DO
doc1.path = BiblioteQ.d/Documentation
doc2.files = Documentation/Contributed/*.docx \
Documentation/Contributed/*.html \
Documentation/Contributed/*.pdf
doc2.path = BiblioteQ.d/Documentation/Contributed
exists(/opt/homebrew/Cellar/libpq/16.4/lib/libpq.dylib) {
installnametool1.extra = install_name_tool -change /Applications/Postgres.app/Contents/Versions/14/lib/libpq.5.dylib /opt/homebrew/Cellar/libpq/16.4/lib/libpq.dylib ./BiblioteQ.d/BiblioteQ.app/Contents/PlugIns/sqldrivers/libqsqlpsql.dylib
}
exists(/usr/local/Cellar/libpq/16.4/lib/libpq.dylib) {
installnametool1.extra = install_name_tool -change /Applications/Postgres.app/Contents/Versions/14/lib/libpq.5.dylib /usr/local/Cellar/libpq/16.4/lib/libpq.dylib ./BiblioteQ.d/BiblioteQ.app/Contents/PlugIns/sqldrivers/libqsqlpsql.dylib
}
installnametool1.path = .
lrelease.extra = $$[QT_INSTALL_BINS]/lrelease biblioteq.osx.pro
lrelease.path = .
lupdate.extra = $$[QT_INSTALL_BINS]/lupdate biblioteq.osx.pro
lupdate.path = .
macdeployqt.extra = $$[QT_INSTALL_BINS]/macdeployqt ./BiblioteQ.app \
-verbose=0 2>/dev/null ; echo;
macdeployqt.path = BiblioteQ.app
postinstall.extra = cp -r BiblioteQ.app BiblioteQ.d/.
postinstall.path = BiblioteQ.d
preinstall.extra = rm -fr BiblioteQ.d/BiblioteQ.app/*
preinstall.path = BiblioteQ.d
sql.files = SQL/*.sql
sql.path = BiblioteQ.d
INSTALLS = preinstall \
macdeployqt \
biblioteq \
conf \
data \
doc1 \
doc2 \
sql \
postinstall \
installnametool1