forked from Workday/warp-core
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle
272 lines (241 loc) · 8.79 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
allprojects {
apply plugin: 'base'
apply plugin: 'java'
apply plugin: 'checkstyle'
apply plugin: 'scala'
apply plugin: 'scalaStyle'
apply plugin: 'idea'
apply plugin: "org.ajoberstar.grgit"
apply plugin: "nebula.dependency-lock"
apply plugin: "nebula.gradle-git-scm"
apply plugin: 'nebula.release'
apply plugin: "nebula.maven-resolved-dependencies"
apply plugin: "org.scoverage"
apply plugin: 'maven-publish'
apply plugin: 'signing'
}
buildscript {
apply from: file("${rootDir}/versionInfo.gradle")
repositories {
jcenter()
}
dependencies {
classpath "com.netflix.nebula:gradle-dependency-lock-plugin:${versions.nebulaDependencyLock}"
classpath "com.netflix.nebula:gradle-git-scm-plugin:${versions.nebulaGit}"
classpath "com.netflix.nebula:nebula-release-plugin:${versions.nebulaRelease}"
classpath "com.netflix.nebula:nebula-publishing-plugin:${versions.nebulaPublish}"
classpath "org.ajoberstar:grgit:${versions.gradleGit}"
classpath "org.github.ngbinh.scalastyle:gradle-scalastyle-plugin_2.11:${versions.scalaStyle}"
classpath "org.scoverage:gradle-scoverage:${versions.gradleScoverage}"
}
}
apply from: file("${rootDir}/versionInfo.gradle")
repositories {
mavenLocal()
jcenter()
}
// teamcity properties come packaged up in 'teamcity' array. set these as system properties so they can all be treated the
// same later when we are forwarding on properties to test jvms.
if (project.hasProperty("teamcity")) {
project.teamcity.each { key, val ->
System.setProperty(key, val)
}
}
sourceCompatibility = 1.8
targetCompatibility = 1.8
// keep in alphabetical order
dependencies {
compile "com.google.code.gson:gson:${versions.gson}"
compile "com.google.guava:guava:${versions.guava}"
compile "com.google.inject:guice:${versions.guice}"
compile "com.h2database:h2:${versions.h2}"
compile "commons-configuration:commons-configuration:${versions.commonsConfiguration}"
compile "commons-io:commons-io:${versions.commonsIo}"
compile "com.typesafe.slick:slick_2.11:${versions.slick}"
compile "com.typesafe.slick:slick-hikaricp_2.11:${versions.slick}"
compile "junit:junit:${versions.junit}"
compile "mysql:mysql-connector-java:${versions.mysqlConnector}"
compile "net.databinder.dispatch:dispatch-core_2.11:${versions.dispatch}"
compile "org.apache.commons:commons-lang3:${versions.commonsLang3}"
compile "org.apache.commons:commons-math3:${versions.math3}"
compile "org.flywaydb:flyway-core:${versions.flyway}"
compile "org.influxdb:influxdb-java:${versions.influxDbClient}"
compile "org.json4s:json4s-jackson_2.11:${versions.json4s}"
compile "org.ow2.asm:asm-tree:${versions.asm}"
compile "org.scala-lang:scala-library:${versions.scalalang}"
compile "org.scala-lang:scala-compiler:${versions.scalalang}"
compile "org.scalatest:scalatest_2.11:${versions.scalatest}"
compile "org.tinylog:slf4j-binding:${versions.slf4jBinding}"
compile "org.tinylog:tinylog:${versions.tinylog}"
scoverage "org.scoverage:scalac-scoverage-plugin_2.11:${versions.scalacScoverage}",
"org.scoverage:scalac-scoverage-runtime_2.11:${versions.scalacScoverage}"
compile files(org.gradle.internal.jvm.Jvm.current().toolsJar)
compile "io.gatling:gatling-core:${versions.gatling}"
compile "io.gatling:gatling-http:${versions.gatling}"
compile "io.gatling:gatling-app:${versions.gatling}"
}
sourceSets {
main {
// joint compilation
scala {
srcDir 'src/main/java'
srcDir 'src/main/scala'
// we want our generated code to live in a separate directory so we can easily skip scalastyle,
// however its convenient to treat this as part of the same source set and compile everything together
srcDir 'src/generated/scala'
}
java {
srcDirs = [] // don't compile Java code twice
}
}
test {
// joint compilation
scala {
srcDir 'src/test/java'
srcDir 'src/test/scala'
}
java {
srcDirs = [] // don't compile Java code twice
}
}
}
task sourcesJar(type: Jar) {
classifier = 'sources'
from sourceSets.main.allSource
}
// fake javadoc jar to pass sonatype rules
// See https://central.sonatype.org/pages/requirements.html
task javadocJar(type: Jar) {
classifier = 'javadoc'
from new File('javadoc-fake')
}
task scaladocJar(type: Jar) {
classifier = 'scaladoc'
from scaladoc.destinationDir
}
scaladoc {
classpath = sourceSets.main.runtimeClasspath
destinationDir file("$rootDir/gh-pages-src/static/scaladoc/${project.name}")
}
task unitTest(type: Test) {
useJUnit {
excludeCategories 'com.workday.warp.common.category.IntegrationTest'
includeCategories 'com.workday.warp.common.category.UnitTest'
}
}
test {
minHeapSize = "500m"
maxHeapSize = "8g"
testLogging {
events 'started', 'passed'
showStandardStreams = true
}
}
task deleteSchema(type: JavaExec, dependsOn: compileTestScala) {
description = "deletes the db schema prior to running tests"
main = "com.workday.warp.persistence.DropCoreSchema"
classpath = sourceSets.main.runtimeClasspath
doLast {
println("gradle task deleted schema")
}
}
scalaStyle {
configLocation = "${rootDir}/scalastyle.xml"
includeTestSourceDirectory = true
source = "src/main/scala"
testSource = "src/test/scala"
}
checkstyle {
toolVersion = "${versions.checkstyle}"
configFile = new File("${rootDir}/checkstyle.xml")
}
tasks.withType(JavaExec).each { task ->
System.properties.each { key, val ->
// TODO see if we need to filter the forwarded properties here
task.systemProperty key, val
}
}
tasks.withType(Test).each { task ->
if (project.hasProperty("shouldDeleteSchema") && Boolean.valueOf(project.shouldDeleteSchema.toString())) {
task.dependsOn(deleteSchema)
}
task.finalizedBy(scalaStyle)
task.finalizedBy(checkstyleMain)
task.finalizedBy(checkstyleTest)
System.properties.each { key, val ->
// TODO see if we need to filter the forwarded properties here
task.systemProperty key, val
}
}
dependencyLock {
includeTransitives = true
}
commitDependencyLock {
message = "(auto) update dependency lock file, version=${project.version.toString()}"
}
scoverage {
// Excluding autogenerated Tables
excludedPackages = ["com.workday.warp.persistence.model", "com.workday.warp.examples"]
excludedFiles = []
}
// Defaults: 75% of Statements. Other types of coverage: Line, Branch
checkScoverage {
coverageType = 'Statement'
minimumRate = 0.92
}
/**
* @return true iff we are building a maven snapshot or a devSnapshot.
*/
static boolean isSnapshot(String inferredVersion) {
inferredVersion.endsWith("-SNAPSHOT") || inferredVersion.contains("-dev.") || inferredVersion.contains(".dev.")
}
publishing {
publications {
mavenJava(MavenPublication) {
groupId = 'com.workday.warp'
artifactId = 'warp-core'
from components.java
artifact sourcesJar
artifact javadocJar
artifact scaladocJar
pom {
name = 'warp-core'
description = 'A library for scientific performance testing.'
url = 'https://workday.github.io/warp-core/'
licenses {
license {
name = 'MIT License'
url = 'https://opensource.org/licenses/mit-license.php'
}
}
developers {
developer {
id = 'tomnis'
name = 'tomas mccandless'
email = '[email protected]'
}
}
scm {
connection = 'scm:git:git://github.com/Workday/warp-core.git'
developerConnection = 'scm:git:ssh://github.com:Workday/warp-core.git'
url = 'https://github.com/Workday/warp-core/tree/master'
}
}
}
}
repositories {
maven {
credentials {
// will be null if these aren't set as project properties
username findProperty("sonatypeUsername")
password findProperty("sonatypePassword")
}
String snapshotsRepoUrl = 'https://oss.sonatype.org/content/repositories/snapshots'
String releasesRepoUrl = 'https://oss.sonatype.org/service/local/staging/deploy/maven2'
url = isSnapshot(version.toString()) ? snapshotsRepoUrl : releasesRepoUrl
}
}
}
signing {
sign publishing.publications.mavenJava
}