-
Notifications
You must be signed in to change notification settings - Fork 5
/
PCRE.pas
2242 lines (1637 loc) · 62 KB
/
PCRE.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// $Id: PCRE.pas,v 1.23 2005/08/27 13:24:39 Renato Exp $
{**************************************************************}
{ }
{ Borland Delphi Wrapper for Philip Hazel's PCRE library }
{ }
{ Author: Renato Mancuso <[email protected]> }
{ }
{ Copyright (C) 2003-2004 Renato Mancuso }
{ }
{==============================================================}
{ }
{ Regular expression support is provided by the PCRE library }
{ package, which is open source software, written by Philip }
{ Hazel, and copyright by the University of Cambridge, }
{ England. }
{ }
{ The latest release of PCRE is always available from: }
{ }
{ ftp://ftp.csx.cam.ac.uk/pub/software/programming/pcre/ }
{ }
{==============================================================}
{ }
{ DISCLAIMER }
{ ---------- }
{ This software is distributed in the hope that it will be }
{ useful, but WITHOUT ANY WARRANTY; without even the implied }
{ warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR }
{ PURPOSE. }
{ }
{**************************************************************}
//
// Revision History
// ----------------
//
// 03-FEB-2008
// David ([email protected]) wrote:
// I notice there is a bug of PCRE Workbench:
// Regex-Replace '1234567890' with '(?<=\d)(?=(\d{3})+$)' to ','
// Result : 1,,234,,567,,890 => ERROR
// Should be: 1,234,567,890
//
// Modified TRegex.Replace and TRegex.Split to use fix
// provided by David
//
// 27-AUG-2005
// Added support for DFA matching
//
// 30-JUN-2005
// Added preliminary support for PCRE 6.1
//
// 26-OCT-2004
// Updated for PCRE 5.0
//
// 01-MAR-2004
// Added support for named capture groups using code
// contributed by Sacha De Vos <[email protected]>
//
// 29-FEB-2004
// Added call to LocaleLock.Free() in unit finalization
// thanks to Miha Vrhovnik - http://simail.sourceforge.net
//
//**************************************************************
unit PCRE;
{$mode delphi}
{$ALIGN ON}
{$MINENUMSIZE 4}
interface
uses
SysUtils;
const
CAPTURE_GROUP_BEFORE_START = -1;
CAPTURE_GROUP_AFTER_END = -2;
CAPTURE_GROUP_ENTIRE_MATCH = 0;
const
INVALID_INDEX_VALUE = -1;
type
// Options used to control compilation of regex patterns
TRegCompileOption =
(
rcoAnchored, // PCRE_ANCHORED
rcoIgnoreCase, // PCRE_CASELESS
rcoDollarEndOnly, // PCRE_DOLLAR_ENDONLY
rcoSingleLine, // PCRE_DOTALL
rcoIgnorePatternWhitespace, // PCRE_EXTENDED
rcoExtra, // PCRE_EXTRA
rcoMultiLine, // PCRE_MULTILINE
rcoUngreedy, // PCRE_UNGREEDY
rcoNoAutoCapture, // PCRE_NO_AUTO_CAPTURE
rcoUTF8, // PCRE_UTF8
rcoNoUTF8Check, // PCRE_NO_UTF8_CHECK
rcoAutoCallout, // PCRE_AUTO_CALLOUT
rcoPartial, // PCRE_PARTIAL
rcoFirstLine, // PCRE_FIRSTLINE
rcoNewLineCR, // PCRE_NEWLINE_CR
rcoNewLineLF, // PCRE_NEWLINE_LF
rcoNewLineCRLF // PCRE_NEWLINE_CRLF
);
// Options used to control matching behavior
TRegMatchOption =
(
rmoAnchored, // PCRE_ANCHORED
rmoNotBOL, // PCRE_NOTBOL
rmoNotEOL, // PCRE_NOTEOL
rmoNotEmpty, // PCRE_NOTEMPTY
rmoNoUTF8Check, // PCRE_NO_UTF8_CHECK
rmoDfaShortest // PCRE_DFA_SHORTEST
);
TRegSplitOption = ( rsoIncludeSeparators );
TRegCompileOptions = set of TRegCompileOption;
TRegMatchOptions = set of TRegMatchOption;
TRegSplitOptions = set of TRegSplitOption;
type
ICaptureGroup = interface
['{2AAF1F28-63F8-4977-95EE-13AAC0E3E866}']
function GetMatched: Boolean; stdcall;
function GetValue: string; stdcall;
function GetIndex: Integer; stdcall;
function GetLength: Integer; stdcall;
property Matched: Boolean
read GetMatched;
property Value: string
read GetValue;
property Index: Integer
read GetIndex;
property Length: Integer
read GetLength;
end;
ICaptureGroupCollection = interface
['{662BAD69-E186-4582-A3EB-568AE049E16A}']
function GetCount: Integer; stdcall;
function GetItem(Index: Integer): ICaptureGroup; stdcall;
function GetItemByName(const Name: string): ICaptureGroup; stdcall;
property Count: Integer
read GetCount;
property Items[Index: Integer]: ICaptureGroup
read GetItem; default;
property ItemsByName[const Name: string]: ICaptureGroup
read GetItemByName;
end;
IMatch = interface(ICaptureGroup)
['{99E6F66B-1D9F-41D6-8C30-497AF04EF2BA}']
function GetGroups: ICaptureGroupCollection; stdcall;
property Success: Boolean
read GetMatched;
property Groups: ICaptureGroupCollection
read GetGroups;
end;
IMatchCollection = interface
['{86D9C75F-754A-4A71-9965-3854DB68F8E9}']
function GetCount: Integer; stdcall;
function GetItem(Index: Integer): IMatch; stdcall;
property Count: Integer
read GetCount;
property Items[Index: Integer]: IMatch
read GetItem; default;
end;
IStringCollection = interface
['{4FC62381-7D61-4399-B22E-4AB27BBC070C}']
function GetCount: Integer; stdcall;
function GetString(Index: Integer): string; stdcall;
property Count: Integer
read GetCount;
property Strings[Index: Integer]: string
read GetString; default;
end;
IDfaMatch = interface
['{66D0477C-0ADB-4BB5-AA0A-73E4F578458B}']
function GetValue: string; stdcall;
function GetIndex: Integer; stdcall;
function GetLength: Integer; stdcall;
property Value: string
read GetValue;
property Index: Integer
read GetIndex;
property Length: Integer
read GetLength;
end;
IDfaMatchCollection = interface
['{4AAC53FA-9681-42D6-8949-086EF141B430}']
function GetCount: Integer; stdcall;
function GetItem(Index: Integer): IDfaMatch; stdcall;
property Count: Integer
read GetCount;
property Items[Index: Integer]: IDfaMatch
read GetItem; default;
end;
TRegexMatchEvaluator = function(theMatch: IMatch): string of object;
TRegexMatchEvent = procedure(theMatch: IMatch) of object;
IRegex = interface
['{C8DA961E-33ED-4C3A-AA9F-400DD9A766EB}']
{ IsMatch }
function IsMatch(const Input : string): Boolean; overload; stdcall;
function IsMatch(const Input : string;
Options : TRegMatchOptions): Boolean; overload; stdcall;
function IsMatch(const Input : string;
Start : Integer): Boolean; overload; stdcall;
function IsMatch(const Input : string;
Start : Integer;
Options : TRegMatchOptions): Boolean; overload; stdcall;
{ Match }
function Match(const Input : string): IMatch; overload; stdcall;
function Match(const Input : string;
Options : TRegMatchOptions): IMatch; overload; stdcall;
function Match(const Input : string;
Start : Integer): IMatch; overload; stdcall;
function Match(const Input : string;
Start : Integer;
Options : TRegMatchOptions): IMatch; overload; stdcall;
{ DFA Match }
function DfaMatch(const Input : string): IDfaMatchCollection; overload; stdcall;
function DfaMatch(const Input : string;
Options : TRegMatchOptions): IDfaMatchCollection; overload; stdcall;
function DfaMatch(const Input : string;
Start : Integer): IDfaMatchCollection; overload; stdcall;
function DfaMatch(const Input : string;
Start : Integer;
Options : TRegMatchOptions): IDfaMatchCollection; overload; stdcall;
{ Matches }
function Matches(const Input : string): IMatchCollection; overload; stdcall;
function Matches(const Input : string;
Options: TRegMatchOptions): IMatchCollection; overload; stdcall;
{ Grep }
procedure Grep(const Input : string;
OnMatch : TRegexMatchEvent); overload; stdcall;
procedure Grep(const Input : string;
Options : TRegMatchOptions;
OnMatch : TRegexMatchEvent); overload; stdcall;
{ Split }
function Split(const Input : string): IStringCollection; overload; stdcall;
function Split(const Input : string;
Options : TRegSplitOptions): IStringCollection; overload; stdcall;
function Split(const Input : string;
Options : TRegSplitOptions;
MatchOptions : TRegMatchOptions): IStringCollection; overload; stdcall;
{ Replace }
function Replace(const Input : string;
const Replacement : string): string; overload; stdcall;
function Replace(const Input : string;
Evaluator : TRegexMatchEvaluator): string; overload; stdcall;
function Replace(const Input : string;
const Replacement : string;
MatchOptions : TRegMatchOptions): string; overload; stdcall;
function Replace(const Input : string;
Evaluator : TRegexMatchEvaluator;
MatchOptions : TRegMatchOptions): string; overload; stdcall;
{ Misc }
function GetOptions: TRegCompileOptions; stdcall;
function GetPattern: string; stdcall;
{ properties }
property Options: TRegCompileOptions
read GetOptions;
property Pattern: string
read GetPattern;
end;
TNamedGroupInfo = record
Name : string;
Index : Integer;
end;
IRegexInfo = interface
['{9BEAD385-793F-441A-8721-D161B2DCA6B7}']
function GetCompiledSize : Cardinal; stdcall;
function GetCaptureCount : Integer; stdcall;
function GetBackRefMax : Integer; stdcall;
function GetFirstChar : Integer; stdcall;
function GetFirstTable : Pointer; stdcall;
function GetLastLiteral : Integer; stdcall;
function GetLocale : string; stdcall;
function GetOptions : TRegCompileOptions; stdcall;
function GetPattern : string; stdcall;
function GetNamedGroupCount : Integer; stdcall;
function GetNamedGroup(Index: Integer): TNamedGroupInfo; stdcall;
property Options: TRegCompileOptions
read GetOptions;
property Pattern: string
read GetPattern;
property CompiledSize: Cardinal
read GetCompiledSize;
property CaptureCount: Integer
read GetCaptureCount;
property BackRefMax: Integer
read GetBackRefMax;
property FirstChar: Integer
read GetFirstChar;
property FirstTable: Pointer
read GetFirstTable;
property LastLiteral: Integer
read GetLastLiteral;
property Locale: string
read GetLocale;
property NamedGroupCount: Integer
read GetNamedGroupCount;
property NamedGroup[Index: Integer]: TNamedGroupInfo
read GetNamedGroup;
end;
type
TRegexLocaleCategory =
(
RXLC_ALL, // = LC_ALL,
RXLC_COLLATE, // = LC_COLLATE,
RXLC_CTYPE, // = LC_CTYPE,
RXLC_MONETARY, // = LC_MONETARY,
RXLC_NUMERIC, // = LC_NUMERIC,
RXLC_TIME // = LC_TIME
);
type
ERegexException = class(Exception);
EBadRegexLocale = class(ERegexException);
ERegexInvalidSubstitutionGroup = class(ERegexException);
ERegexBadGroupName = class(ERegexException);
function RegexCreate(const thePattern : string): IRegex; overload;
function RegexCreate(const thePattern : string;
theOptions : TRegCompileOptions): IRegex; overload;
function RegexCreate(const thePattern : string;
const theLocale : string;
theLocaleCategory: TRegexLocaleCategory = RXLC_ALL): IRegex; overload;
function RegexCreate(const thePattern : string;
theOptions : TRegCompileOptions;
const theLocale : string;
theLocaleCategory: TRegexLocaleCategory = RXLC_ALL): IRegex; overload;
function EncodeRegCompileOptions(theOptions : TRegCompileOptions): LongWord;
function DecodeRegCompileOptions(theOptions : LongWord): TRegCompileOptions;
function EncodeRegMatchOptions (theOptions : TRegMatchOptions): LongWord;
function DecodeRegMatchOptions (theOptions : LongWord): TRegMatchOptions;
implementation
uses
Classes,
SyncObjs,
Math,
pcre_dll;
{ ********************************************************* }
{ ********************************************************* }
{ ********************************************************* }
type
INameIndexLookup = interface
['{4EB901AE-50F9-4552-84B6-1676613B6F0E}']
function GetGroupIndex(const theName: string): Integer;
procedure AddMapping(const theName: string; theIndex: Integer);
function GetMappingCount: Integer;
function GetMappingAt(theIndex: Integer): TNamedGroupInfo;
end;
TNameIndexLookup = class(TInterfacedObject, INameIndexLookup)
private
FMappings : TStringList;
public
constructor Create;
destructor Destroy; override;
// INameIndexLookup
function GetGroupIndex(const theName: string): Integer;
procedure AddMapping(const theName: string; theIndex: Integer);
function GetMappingCount: Integer;
function GetMappingAt(theIndex: Integer): TNamedGroupInfo;
end;
TRegexLocale = class
private
FNlsTable: TPcre_tableH;
FDispose : Boolean;
FLocale : string;
public
constructor Create(const theLocale: string; theLocaleCategory: TRegexLocaleCategory);
destructor Destroy; override;
property Locale: string
read FLocale;
property CharTable: TPcre_tableH
read FNlsTable;
end;
TRegexStringCollection = class(TInterfacedObject, IStringCollection)
private
FStrings : TStringList;
public
constructor Create;
destructor Destroy; override;
procedure Add(const S: string);
{ IStringCollection }
function GetCount: Integer; stdcall;
function GetString(Index: Integer): string; stdcall;
end;
TRegexMatchCollection = class(TInterfacedObject, IMatchCollection)
private
FList : TInterfaceList;
public
constructor Create;
destructor Destroy; override;
procedure Add(Element: IMatch);
{ IMatchCollection }
function GetCount: Integer; stdcall;
function GetItem(Index: Integer): IMatch; stdcall;
end;
TOVector = array of Integer;
TMatchPos = record
First : Integer;
Last : Integer;
end;
TRegexMatch = class(TInterfacedObject, IMatch, ICaptureGroupCollection)
private
FSubject : string;
FCount : Integer;
FMatches : TOvector;
FNames : INameIndexLookup;
public
constructor Create(const S: string; var VOffset: TOVector; const Names: INameIndexLookup);
destructor Destroy; override;
function InternalGetMatchPos(Index: Integer): TMatchPos;
function InternalGetMatched(Index: Integer): Boolean;
function InternalGetValue(Index: Integer): string;
function InternalGetIndex(Index: Integer): Integer;
function InternalGetLength(Index: Integer): Integer;
{ ICaptureGroup }
function GetMatched: Boolean; stdcall;
function GetValue: string; stdcall;
function GetIndex: Integer; stdcall;
function GetLength: Integer; stdcall;
{ IMatch }
function GetGroups: ICaptureGroupCollection; stdcall;
{ ICaptureGroupCollection }
function GetCount: Integer; stdcall;
function GetItem(Index: Integer): ICaptureGroup; stdcall;
function GetItemByName(const Name: string): ICaptureGroup; stdcall;
end;
TRegexCaptureGroup = class(TInterfacedObject, ICaptureGroup)
private
FMatch : TRegexMatch;
FIndex : Integer;
public
constructor Create(Match: TRegexMatch; Index: Integer);
destructor Destroy; override;
{ ICaptureGroup }
function GetMatched: Boolean; stdcall;
function GetValue: string; stdcall;
function GetIndex: Integer; stdcall;
function GetLength: Integer; stdcall;
end;
TDfaMatchCollection = class(TInterfacedObject, IDfaMatchCollection)
private
FSubject : string;
FCount : Integer;
FMatches : TOvector;
public
constructor Create(const S: string; var VOffset: TOVector);
destructor Destroy; override;
function InternalGetMatchPos(Index: Integer): TMatchPos;
function InternalGetValue(Index: Integer): string;
function InternalGetIndex(Index: Integer): Integer;
function InternalGetLength(Index: Integer): Integer;
{ IDfaMatchCollection }
function GetCount: Integer; stdcall;
function GetItem(Index: Integer): IDfaMatch; stdcall;
end;
TDfaMatch = class(TInterfacedObject, IDfaMatch)
private
FMatchCollection: TDfaMatchCollection;
FIndex: Integer;
public
constructor Create(MatchCollection: TDfaMatchCollection; Index: Integer);
destructor Destroy; override;
{ IDfaMatch }
function GetValue: string; stdcall;
function GetIndex: Integer; stdcall;
function GetLength: Integer; stdcall;
end;
TRegex = class(TInterfacedObject, IRegex, IRegexInfo)
private
FPattern : string;
FOptions : TRegCompileOptions;
FRegex : TPcreH;
FRegExtra : TPcre_extraH;
FLocaleInfo : TRegexLocale;
FNames : INameIndexLookup;
procedure CompilePattern;
procedure RetrieveNames;
procedure PcreCheck(ErrorCode: Integer);
public
constructor Create(const Pattern : string;
Options : TRegCompileOptions;
const Locale : string;
LocaleCategory : TRegexLocaleCategory = RXLC_ALL);
destructor Destroy; override;
{ IRegex }
function IsMatch(const Input: string): Boolean; overload; stdcall;
function IsMatch(const Input: string; Options: TRegMatchOptions): Boolean; overload; stdcall;
function IsMatch(const Input: string; Start: Integer): Boolean; overload; stdcall;
function IsMatch(const Input: string; Start: Integer; Options: TRegMatchOptions): Boolean; overload; stdcall;
function Match(const Input: string): IMatch; overload; stdcall;
function Match(const Input: string; Options: TRegMatchOptions): IMatch; overload; stdcall;
function Match(const Input: string; Start: Integer): IMatch; overload; stdcall;
function Match(const Input: string; Start: Integer; Options: TRegMatchOptions): IMatch; overload; stdcall;
function DfaMatch(const Input : string): IDfaMatchCollection; overload; stdcall;
function DfaMatch(const Input : string;
Options : TRegMatchOptions): IDfaMatchCollection; overload; stdcall;
function DfaMatch(const Input : string;
Start : Integer): IDfaMatchCollection; overload; stdcall;
function DfaMatch(const Input : string;
Start : Integer;
Options : TRegMatchOptions): IDfaMatchCollection; overload; stdcall;
function Matches(const Input: string): IMatchCollection; overload; stdcall;
function Matches(const Input: string; Options: TRegMatchOptions): IMatchCollection; overload; stdcall;
procedure Grep(const Input: string; OnMatch: TRegexMatchEvent); overload; stdcall;
procedure Grep(const Input: string; Options: TRegMatchOptions; OnMatch: TRegexMatchEvent); overload; stdcall;
function Split(const Input: string): IStringCollection; overload; stdcall;
function Split(const Input: string; Options: TRegSplitOptions): IStringCollection; overload; stdcall;
function Split(const Input: string; Options: TRegSplitOptions; MatchOptions: TRegMatchOptions): IStringCollection; overload; stdcall;
function Replace(const Input: string; const Replacement: string): string; overload; stdcall;
function Replace(const Input: string; Evaluator: TRegexMatchEvaluator): string; overload; stdcall;
function Replace(const Input: string; const Replacement: string; MatchOptions: TRegMatchOptions): string; overload; stdcall;
function Replace(const Input: string; Evaluator: TRegexMatchEvaluator; MatchOptions: TRegMatchOptions): string; overload; stdcall;
function GetOptions: TRegCompileOptions; stdcall;
function GetPattern: string; stdcall;
{ IRegexInfo }
function GetCompiledSize: Cardinal; stdcall;
function GetCaptureCount: Integer; stdcall;
function GetBackRefMax: Integer; stdcall;
function GetFirstChar: Integer; stdcall;
function GetFirstTable: Pointer; stdcall;
function GetLastLiteral: Integer; stdcall;
function GetLocale: string; stdcall;
function GetNamedGroupCount : Integer; stdcall;
function GetNamedGroup(Index: Integer): TNamedGroupInfo; stdcall;
end;
TSubstitute = class(TObject)
private
FMatch : IMatch;
public
constructor Create(theMatch: IMatch);
function RegexSubstitute(Match: IMatch): string;
end;
{ ********************************************************* }
{ ********************************************************* }
{ ********************************************************* }
{ RegexCreate }
//===========================================================================
function RegexCreate(const thePattern: string): IRegex;
begin
Result := RegexCreate(thePattern, [], 'C');
end;
//===========================================================================
function RegexCreate(const thePattern: string; theOptions: TRegCompileOptions): IRegex;
begin
Result := RegexCreate(thePattern, theOptions, 'C');
end;
//===========================================================================
function RegexCreate(const thePattern : string;
const theLocale : string;
theLocaleCategory : TRegexLocaleCategory = RXLC_ALL): IRegex;
begin
Result := RegexCreate(thePattern, [], theLocale, theLocaleCategory);
end;
//===========================================================================
function RegexCreate(const thePattern : string;
theOptions : TRegCompileOptions;
const theLocale : string;
theLocaleCategory: TRegexLocaleCategory = RXLC_ALL): IRegex;
begin
Result := TRegex.Create(thePattern, theOptions, theLocale, theLocaleCategory);
end;
//===========================================================================
{ Utility functions}
function EncodeRegCompileOptions(theOptions: TRegCompileOptions): LongWord;
begin
Result := 0;
if rcoAnchored in theOptions then
Result := Result or PCRE_ANCHORED;
if rcoIgnoreCase in theOptions then
Result := Result or PCRE_CASELESS;
if rcoDollarEndOnly in theOptions then
Result := Result or PCRE_DOLLAR_ENDONLY;
if rcoSingleLine in theOptions then
Result := Result or PCRE_DOTALL;
if rcoIgnorePatternWhitespace in theOptions then
Result := Result or PCRE_EXTENDED;
if rcoExtra in theOptions then
Result := Result or PCRE_EXTRA;
if rcoMultiLine in theOptions then
Result := Result or PCRE_MULTILINE;
if rcoUngreedy in theOptions then
Result := Result or PCRE_UNGREEDY;
if rcoNoAutoCapture in theOptions then
Result := Result or PCRE_NO_AUTO_CAPTURE;
if rcoUTF8 in theOptions then
Result := Result or PCRE_UTF8;
if rcoNoUTF8Check in theOptions then
Result := Result or PCRE_NO_UTF8_CHECK;
if rcoAutoCallout in theOptions then
Result := Result or PCRE_AUTO_CALLOUT;
if rcoPartial in theOptions then
Result := Result or PCRE_PARTIAL;
if rcoFirstLine in theOptions then
Result := Result or PCRE_FIRSTLINE;
if rcoNewLineCR in theOptions then
Result := Result or PCRE_NEWLINE_CR;
if rcoNewLineLF in theOptions then
Result := Result or PCRE_NEWLINE_LF;
if rcoNewLineCRLF in theOptions then
Result := Result or PCRE_NEWLINE_CRLF;
end;
//===========================================================================
function DecodeRegCompileOptions(theOptions: LongWord): TRegCompileOptions;
begin
Result := [];
if (theOptions and PCRE_ANCHORED <> 0) then
Include(Result, rcoAnchored);
if (theOptions and PCRE_CASELESS <> 0) then
Include(Result, rcoIgnoreCase);
if (theOptions and PCRE_DOLLAR_ENDONLY <> 0) then
Include(Result, rcoDollarEndOnly);
if (theOptions and PCRE_DOTALL <> 0) then
Include(Result, rcoSingleLine);
if (theOptions and PCRE_EXTENDED <> 0) then
Include(Result, rcoIgnorePatternWhitespace);
if (theOptions and PCRE_EXTRA <> 0) then
Include(Result, rcoExtra);
if (theOptions and PCRE_MULTILINE <> 0) then
Include(Result, rcoMultiLine);
if (theOptions and PCRE_UNGREEDY <> 0) then
Include(Result, rcoUngreedy);
if (theOptions and PCRE_NO_AUTO_CAPTURE <> 0) then
Include(Result, rcoNoAutoCapture);
if (theOptions and PCRE_UTF8 <> 0) then
Include(Result, rcoUTF8);
if (theOptions and PCRE_NO_UTF8_CHECK <> 0) then
Include(Result, rcoNoUTF8Check);
if (theOptions and PCRE_AUTO_CALLOUT <> 0) then
Include(Result, rcoAutoCallout);
if (theOptions and PCRE_PARTIAL <> 0) then
Include(Result, rcoPartial);
if (theOptions and PCRE_FIRSTLINE <> 0) then
Include(Result, rcoFirstLine);
if (theOptions and PCRE_NEWLINE_CR <> 0) then
Include(Result, rcoNewLineCR);
if (theOptions and PCRE_NEWLINE_LF <> 0) then
Include(Result, rcoNewLineLF);
if (theOptions and PCRE_NEWLINE_CRLF <> 0) then
Include(Result, rcoNewLineCRLF);
end;
//===========================================================================
function EncodeRegMatchOptions(theOptions: TRegMatchOptions): LongWord;
begin
Result := 0;
if rmoAnchored in theOptions then
Result := Result or PCRE_ANCHORED;
if rmoNotBOL in theOptions then
Result := Result or PCRE_NOTBOL;
if rmoNotEOL in theOptions then
Result := Result or PCRE_NOTEOL;
if rmoNotEmpty in theOptions then
Result := Result or PCRE_NOTEMPTY;
if rmoNoUTF8Check in theOptions then
Result := Result or PCRE_NO_UTF8_CHECK;
if rmoDfaShortest in theOptions then
Result := Result or PCRE_DFA_SHORTEST;
end;
//===========================================================================
function DecodeRegMatchOptions(theOptions: LongWord): TRegMatchOptions;
begin
Result := [];
if (theOptions and PCRE_ANCHORED <> 0) then
Include(Result, rmoAnchored);
if (theOptions and PCRE_NOTBOL <> 0) then
Include(Result, rmoNotBOL);
if (theOptions and PCRE_NOTEOL <> 0) then
Include(Result, rmoNotEOL);
if (theOptions and PCRE_NOTEMPTY <> 0) then
Include(Result, rmoNotEmpty);
if (theOptions and PCRE_NO_UTF8_CHECK <> 0) then
Include(Result, rmoNoUTF8Check);
if (theOptions and PCRE_DFA_SHORTEST <> 0) then
Include(Result, rmoDfaShortest);
end;
//===========================================================================
constructor TSubstitute.Create(theMatch: IMatch);
begin
inherited Create();
FMatch := theMatch;
end;
//===========================================================================
function TSubstitute.RegexSubstitute(Match: IMatch): string;
const
REGEX_SUBST_DOLLAR = '$';
REGEX_SUBST_ALL_MATCH = '&';
REGEX_SUBST_BEFORE_MATCH = '`';
REGEX_SUBST_AFTER_MATCH = '''';
REGEX_SUBST_LAST_GROUP = '+';
REGEX_SUBST_ALL_INPUT = '_';
REGEX_SUBST_NAMED_GROUP = '{';
var
theSubstitution : string;
theIndex : Integer;
begin
theSubstitution := Match.Groups[1].Value;
case theSubstitution[1] of
REGEX_SUBST_DOLLAR : Result := '$';
REGEX_SUBST_NAMED_GROUP : Result := FMatch.Groups.ItemsByName[Match.Groups[2].Value].Value;
REGEX_SUBST_ALL_MATCH : Result := FMatch.Value;
REGEX_SUBST_BEFORE_MATCH : Result := FMatch.Groups[CAPTURE_GROUP_BEFORE_START].Value;
REGEX_SUBST_AFTER_MATCH : Result := FMatch.Groups[CAPTURE_GROUP_AFTER_END].Value;
REGEX_SUBST_LAST_GROUP : Result := FMatch.Groups[FMatch.Groups.Count - 1].Value;
REGEX_SUBST_ALL_INPUT : Result := FMatch.Groups[CAPTURE_GROUP_BEFORE_START].Value +
FMatch.Value +
FMatch.Groups[CAPTURE_GROUP_AFTER_END].Value;
else
// it must be a number
theIndex := StrToInt(theSubstitution);
if theIndex >= FMatch.Groups.Count then
raise ERegexInvalidSubstitutionGroup.CreateFmt('Invalid substitution variable $%d',
[theIndex]);
Result := FMatch.Groups[theIndex].Value;
end;
end;
//===========================================================================
var
RegexSubstitute : TRegex;
//===========================================================================
function Substitute(const Replace: string; theMatch: IMatch): string;
var
theAction : TSubstitute;
begin
theAction := TSubstitute.Create(theMatch);
try
Result := RegexSubstitute.Replace(Replace, theAction.RegexSubstitute, []);
finally
theAction.Free();
end;
end;
//===========================================================================
{ TRegexLocale }
var
LocaleLock : TCriticalSection;
//===========================================================================
function GetLocaleTable(const theLocale : string;
theLocaleCategory : Integer;
var theCharTable : TPcre_tableH): string;
var
szLocale : PChar;
begin
LocaleLock.Enter;
try
szLocale := pcre_setlocale(theLocaleCategory, PChar(theLocale));
if szLocale = nil then
begin
raise EBadRegexLocale.CreateFmt('Invalid locale string %s or invalid locale category %d',
[theLocale, theLocaleCategory]);
end;
theCharTable := pcre_maketables();
if theCharTable = nil then
OutOfMemoryError;
Result := szLocale;
finally
LocaleLock.Leave;
end;
end;
//===========================================================================
constructor TRegexLocale.Create(const theLocale : string;
theLocaleCategory : TRegexLocaleCategory);
begin
inherited Create;
if (theLocale = 'C') and (theLocaleCategory = RXLC_ALL) then
begin
FNlsTable := nil;
FLocale := 'C';
FDispose := false;