math.nbl

//------------------------------------//
// Copyright 2024 Nam Nguyen
// Licensed under Apache License v2.0
//------------------------------------//

mut PI = 3.1415926535897932384626433832795028841971;

fun factorial(n)
{
    if (n == 0 or n == 1)
    {
        return 1;
    }

    return n * factorial(n - 1);
}

fun sin(x)
{
    mut result = 0;

    for (mut i = 0; i < 20; i += 1)
    {
        mut sign = -1 ** i;
        mut term = (x ** (2 * i + 1)) / factorial(2 * i + 1);
        result += sign * term;
    }

    return result;
}

fun cos(x)
{
    mut result = 0;

    for (mut i = 0; i < 20; i += 1)
    {
        mut sign = -1 ** i;
        mut term = (x ** (2 * i)) / factorial(2 * i);
        result += sign * term;
    }

    return result;
}

fun tan(x)
{
    return sin(x) / cos(x);
}

fun cot(x)
{
    return cos(x) / sin(x);
}

fun exp(x)
{
    mut result = 1;
    mut term = 1;

    for (mut i = 1; i < 20; i += 1)
    {
        term = term * x / i;
        result = result + term;
    }

    return result;
}

fun ln(x)
{
    if (x <= 0)
    {
        return 0 / 0; // error
    }

    mut y = (x - 1) / (x + 1);
    mut y2 = y * y;
    mut result = 0;
    mut term = y;

    for (mut i = 1; i < 100; i += 2)
    {
        result = result + term / i;
        term = term * y2;
    }

    return 2 * result;
}

fun log10(x)
{
    return ln(x) / ln(10);
}

fun log2(x)
{
    return ln(x) / ln(2);
}

fun log(x, b)
{
    return ln(x) / ln(b);
}

fun sqrt(x)
{
    if (x < 0)
    {
        return 0 / 0; // error
    }

    mut guess = x;
    mut epsilon = 0.000001;

    while ((guess * guess - x) > epsilon)
    {
        guess = (guess + x / guess) / 2;
    }

    return guess;
}

fun max(arg1, arg2)
{
    if (arg1 >= arg2)
        return arg1;
    return arg2;
}

fun abs(num)
{
    if (num < 0)
        return 0 - num;
    return num;
}