SConscript.core

# -*- mode: python -*-
# Enemy Territory build script
# TTimo <ttimo@idsoftware.com>
# http://scons.sourceforge.net

import sys, os
import scons_utils

Import( 'GLOBALS' )
Import( GLOBALS )

server_string = """
sv_bot.c
sv_ccmds.c
sv_client.c
sv_game.c
sv_init.c
sv_main.c
sv_net_chan.c
sv_snapshot.c
sv_world.c"""

server_list = scons_utils.BuildList( 'server', server_string )

qcommon_string = """
cm_load.c
cm_patch.c
cm_polylib.c
cm_test.c
cm_trace.c
cmd.c
common.c
cvar.c
files.c
huffman.c
md4.c
msg.c
net_chan.c
unzip.c
vm.c
vm_interpreted.c"""

if ( cpu == 'x86' ):
	qcommon_string += " vm_x86.c"

qcommon_list = scons_utils.BuildList( 'qcommon', qcommon_string )

linux_sources = [
        'unix/linux_signals.c',
        'unix/unix_main.c',
        'unix/unix_net.c',
        'unix/unix_shared.c',
        'game/q_shared.c',
        'game/q_math.c',
#        'unix/matha.S'
]

mac_sources = [
	'game/q_shared.c',
	'game/q_math.c',
	'mac/mac_main.cpp',
	'mac/mac_input.cpp',
	'mac/mac_glimp.cpp',
	'mac/mac_files.cpp',
	'mac/mac_net.cpp',
	'mac/mac_console.c',
	'mac/mac_snddma.c',
	'mac/CarbonMouse.cpp',
	'mac/mac_event.cpp',
#	'mac/HID Manager/HID_Configure.c',
#	'mac/HID Manager/HID_CFM.c',
	'mac/MacPrefs.cpp',
	'mac/PickMonitor/pickmonitor.cpp',
	'mac/PickMonitor/userpane.cpp',
	'mac/mac_qgl.c',
	'mac/mac_specific.cpp',
	'mac/AGLUtils.cpp',
	'mac/CDrawSprocket.cpp'
]

win32_sources = [
	'win32/win_main.c',
	'win32/win_net.c',
	'win32/win_shared.c',
	'win32/win_glimp.c',
	'win32/win_wndproc.c',
	'win32/win_syscon.c',
        'game/q_shared.c',
        'game/q_math.c',
]

botlib_list = [
	'be_aas_bspq3.c',
	'be_aas_cluster.c',
	'be_aas_debug.c',
	'be_aas_entity.c',
	'be_aas_file.c',
	'be_aas_main.c',
	'be_aas_move.c',
	'be_aas_optimize.c',
	'be_aas_reach.c',
	'be_aas_route.c',
	'be_aas_routealt.c',
	'be_aas_routetable.c',
	'be_aas_sample.c',
	'be_ai_char.c',
	'be_ai_chat.c',
	'be_ai_gen.c',
	'be_ai_goal.c',
	'be_ai_move.c',
	'be_ai_weap.c',
	'be_ai_weight.c',
	'be_ea.c',
	'be_interface.c',
	'l_crc.c',
	'l_libvar.c',
	'l_log.c',
	'l_memory.c',
	'l_precomp.c',
	'l_script.c',
	'l_struct.c'
]

botlib_env = g_env.Clone()
botlib_env.Append( CPPDEFINES = [ 'BOTLIB' ] )

botlib_objs = []
for i in botlib_list:
	botlib_objs.append( botlib_env.StaticObject( os.path.join( 'botlib', i ) ) )

staticx11_libs = [ 'libXxf86dga.a', 'libXxf86vm.a' ]
if ( os.path.exists( os.path.join( '/usr/lib', staticx11_libs[0] ) ) ):
	staticx11_libs = [ os.path.join( '/usr/lib', i ) for i in staticx11_libs ]
else:
	staticx11_libs = [ os.path.join( '/usr/X11R6/lib', i ) for i in staticx11_libs ]

if ( g_os == 'Linux' ):
	nasm_env = Environment( tools = [ 'nasm' ] )
	nasm_env['ASFLAGS'] = '-f elf'
	snapvector = nasm_env.StaticObject( 'unix/snapvector.asm' )

	# gas assembly, with preprocessing
	gas_env = Environment( tools = [ 'gcc', 'gas' ] )
	gas_env.Append( CPPDEFINES = [ 'ELF' ] )
	gas_env.Append( ASFLAGS = [ '-m32', '-x', 'assembler-with-cpp' ] )
	matha = gas_env.StaticObject( 'unix/matha.spp' )
    #snd_mixa = gas_env.StaticObject( 'unix/snd_mixa.spp' )

splines_env = g_env.Clone()
#splines_lib = splines_env.StaticLibrary( splines_list )

local_env = g_env.Clone()

if ( g_os == 'Linux' ):
	local_env.Append( LIBS = [ 'dl' ] )
	local_env.Append( CPPDEFINES = [ 'DEDICATED' ] )
	local_env.Append( LIBS = [ 'm' ] )

	if gcc3 == 0:
		g_env.Append(LINKFLAGS=[ os.popen( g_env['CXX'] + ' -print-file-name=libstdc++.a' ).read().rstrip() ])
	else:
		local_env['ENV']['CC'] = g_env['CC']
		local_env['LINK'] = 'unix/staticlinkcpp.sh'
elif ( g_os == 'win32' ):
	local_env.Append( LIBS = [ 'm', 'winmm', 'wsock32', 'gdi32', 'ole32', 'iphlpapi' ] )
	local_env.Append( CPPDEFINES = [ 'DEDICATED', 'WIN32', '_WINDOWS', '_M_IX86' ] )
	#local_env.Append( CPPFLAGS = [ '-I', 'C:\Program Files\Microsoft DirectX SDK (June 2010)\Include'] )
	local_env['LINK'] = g_env['CXX']
elif ( g_os == 'Darwin' ):
	local_env.Append( LINKFLAGS = [ '-framework', 'AGL', '-framework', 'OpenGL', '-framework', 'Carbon', '-framework', 'IOKit', '-framework', 'DrawSprocket', '-lcurl' ] )

if ( MASTER != '' ):
	local_env.Append( CPPDEFINES = [ 'MASTER_SERVER_NAME=\\"%s\\"' % MASTER ] )

source_list = server_list + qcommon_list
if ( g_os == 'Linux' ):
	source_list += linux_sources + snapvector + matha
elif ( g_os == 'win32' ):
	source_list += win32_sources
elif ( g_os == 'Darwin' ):
	if ( BUILD == 'release' ):
		local_env.Append( CPPFLAGS = [ '-include', 'mac/MacPrefix.h' ] )
	else:
		local_env.Append( CPPFLAGS = [ '-include', 'mac/MacPrefixDebug.h' ] )
	mac_objects = []
	for i in mac_sources:
		mac_objects.append( local_env.StaticObject( i ) )
	source_list += mac_objects

source_list += botlib_objs


source_list += [ 'null/null_client.c', 'null/null_input.c', 'null/null_snddma.c', 'qcommon/dl_main_stubs.c' ]
#source_list += splines_lib

ret = local_env.Program( target = 'et', source = source_list )
Return( 'ret' )