generated from kwame-mintah/terraform-azurerm-template
-
Notifications
You must be signed in to change notification settings - Fork 0
/
tfstate-storage.tf
189 lines (165 loc) · 5.5 KB
/
tfstate-storage.tf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
# Create Azure Storage for Terraform
locals {
common_tags = merge(
var.tags
)
}
resource "random_string" "resource_code" {
length = 5
special = false
upper = false
}
resource "azurerm_resource_group" "environment_rg" {
name = "ai-102-${var.environment}-resources"
location = var.location
tags = merge(
local.common_tags
)
}
resource "azurerm_storage_account" "tfstate" {
name = "tfstate${var.environment}${random_string.resource_code.result}"
resource_group_name = azurerm_resource_group.environment_rg.name
location = azurerm_resource_group.environment_rg.location
account_tier = "Standard"
account_replication_type = "GRS"
account_kind = "StorageV2"
min_tls_version = "TLS1_2"
public_network_access_enabled = true # Ideally this would be false, however needs a VNET to be created.
enable_https_traffic_only = true
allow_nested_items_to_be_public = false
blob_properties {
delete_retention_policy {
days = 7
}
}
network_rules {
default_action = "Deny"
bypass = ["Metrics", "AzureServices"]
ip_rules = [var.personal_ip_address] # Should be your own IP address, or won't be able to apply changes.
}
queue_properties {
hour_metrics {
enabled = true
include_apis = true
version = "1.0"
retention_policy_days = 10
}
minute_metrics {
enabled = true
include_apis = true
version = "1.0"
retention_policy_days = 10
}
logging {
delete = true
read = true
write = true
version = "1.0"
retention_policy_days = 10
}
}
identity {
type = "SystemAssigned"
}
lifecycle {
ignore_changes = [
customer_managed_key
]
}
tags = merge(
local.common_tags
)
}
resource "azurerm_storage_container" "tfstate" {
name = "tfstate-${var.environment}"
storage_account_name = azurerm_storage_account.tfstate.name
container_access_type = "private"
}
# Customer Managed Key (CMK) for storage
resource "azurerm_key_vault" "tfstate_key_vault" {
name = "tfstate-${var.environment}-cmk"
location = azurerm_resource_group.environment_rg.location
resource_group_name = azurerm_resource_group.environment_rg.name
tenant_id = data.azurerm_client_config.current.tenant_id
sku_name = "standard"
soft_delete_retention_days = 7
purge_protection_enabled = true
network_acls {
bypass = "AzureServices"
default_action = "Deny"
ip_rules = [var.personal_ip_address] # Should be your own IP address, or won't be able to apply changes.
}
tags = merge(
local.common_tags
)
}
resource "azurerm_key_vault_access_policy" "tfstate_storage" {
key_vault_id = azurerm_key_vault.tfstate_key_vault.id
tenant_id = data.azurerm_client_config.current.tenant_id
object_id = azurerm_storage_account.tfstate.identity[0].principal_id
secret_permissions = ["Get"]
key_permissions = [
"Get",
"UnwrapKey",
"WrapKey"
]
}
resource "azurerm_key_vault_key" "tfstate_key_vault_key" {
name = "tfstate-${var.environment}-key"
key_vault_id = azurerm_key_vault.tfstate_key_vault.id
key_type = "RSA"
key_size = 2048
key_opts = ["decrypt", "encrypt", "sign", "unwrapKey", "verify", "wrapKey"]
expiration_date = "2024-12-31T00:00:00Z"
tags = merge(
local.common_tags
)
depends_on = [
azurerm_key_vault.tfstate_key_vault
]
}
resource "azurerm_storage_account_customer_managed_key" "tfstate_cmk" {
storage_account_id = azurerm_storage_account.tfstate.id
key_vault_id = azurerm_key_vault.tfstate_key_vault.id
key_name = azurerm_key_vault_key.tfstate_key_vault_key.name
}
# Storage account logging for blobs
resource "azurerm_log_analytics_workspace" "tfstate_analytics_workspace" {
name = "tfstate-${var.environment}-workspace"
location = azurerm_resource_group.environment_rg.location
resource_group_name = azurerm_resource_group.environment_rg.name
sku = "PerGB2018"
retention_in_days = 30
tags = merge(
local.common_tags
)
}
resource "azurerm_log_analytics_storage_insights" "tfstate_analytics_storage_insights" {
name = "tfstate-${var.environment}-storage-insight-config"
resource_group_name = azurerm_resource_group.environment_rg.name
workspace_id = azurerm_log_analytics_workspace.tfstate_analytics_workspace.id
storage_account_id = azurerm_storage_account.tfstate.id
storage_account_key = azurerm_storage_account.tfstate.primary_access_key
}
# Diagnostic Setting for storage account
resource "azurerm_monitor_diagnostic_setting" "tfstate_diagnostic_setting" {
name = "${var.environment}-tfstate-diagnostic"
target_resource_id = azurerm_storage_account.tfstate.id
log_analytics_workspace_id = azurerm_log_analytics_workspace.tfstate_analytics_workspace.id
metric {
category = "Transaction"
retention_policy {
enabled = true
days = 7
}
}
metric {
category = "Capacity"
enabled = false
retention_policy {
days = 0
enabled = false
}
}
depends_on = [azurerm_log_analytics_workspace.tfstate_analytics_workspace]
}