-
Notifications
You must be signed in to change notification settings - Fork 4
/
build.gradle.kts
94 lines (81 loc) · 2.89 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
plugins {
buildsrc.conventions.lang.`kotlin-multiplatform`
buildsrc.conventions.publishing
buildsrc.conventions.`git-branch-publish`
buildsrc.conventions.`yaml-testing`
id("dev.adamko.dokkatoo-html") version "2.4.0"
id("org.jetbrains.kotlinx.binary-compatibility-validator") version "0.16.3"
}
group = "it.krzeminski"
version = "3.0.3-SNAPSHOT"
description = "SnakeYAML Engine KMP"
apiValidation {
ignoredProjects += listOf("snake-kmp-benchmarks")
}
kotlin {
sourceSets {
commonMain {
dependencies {
implementation("com.squareup.okio:okio:3.9.1")
implementation("net.thauvin.erik.urlencoder:urlencoder-lib:1.5.0")
}
}
commonTest {
kotlin.srcDirs(tasks.yamlTestSuiteDataSources)
dependencies {
implementation(project.dependencies.platform("io.kotest:kotest-bom:5.9.1"))
implementation("io.kotest:kotest-framework-engine")
implementation("io.kotest:kotest-framework-api")
implementation("io.kotest:kotest-assertions-core")
}
}
jvmTest {
dependencies {
implementation("org.junit.jupiter:junit-jupiter-engine:5.11.2")
implementation("io.kotest:kotest-runner-junit5")
implementation("com.google.guava:guava:33.3.1-jre")
}
}
}
}
tasks.withType<Test>().configureEach {
environment(
"EnvironmentKey1" to "EnvironmentValue1",
"EnvironmentEmpty" to "",
)
}
dokkatoo {
moduleName = "SnakeYAML Engine KMP"
val docsDir = layout.projectDirectory.dir("docs")
dokkatooSourceSets.configureEach {
includes.from(docsDir.file("modules.md"))
externalDocumentationLinks.register("okio") {
packageListUrl("https://square.github.io/okio/3.x/okio/okio/package-list")
url("https://square.github.io/okio/3.x/okio/")
}
sourceLink {
localDirectory = layout.projectDirectory
val projectVersion = provider { project.version.toString() }
remoteUrl = projectVersion.map { version ->
// if project version matches SemVer, then point the URL to a tag - otherwise, point to main
val remoteVersion =
if (version.matches(Regex("""[1-9][0-9]*\.[1-9][0-9]*\.[1-9][0-9]*"""))) {
"v${version}"
} else {
"main"
}
uri("https://github.com/krzema12/snakeyaml-engine-kmp/blob/$remoteVersion")
}
}
}
pluginsConfiguration {
html {
homepageLink = "https://github.com/krzema12/snakeyaml-engine-kmp"
customAssets.from(
docsDir.files(
"img/homepage.svg",
)
)
}
}
}