From 890161a7e02d138fdc56202c86f8fb78b7429893 Mon Sep 17 00:00:00 2001
From: finanalyst <rnhainsworth@gmail.com>
Date: Sat, 16 Dec 2023 10:51:47 +0000
Subject: [PATCH] start work on numbered headings

---
 .gitignore                |   1 +
 lib/ProcessedPod.rakumod  | 214 ++++++++++++++--------
 xt/75-numbered.rakutest   | 374 ++++++++++++++++++++++++++++++++++++++
 xt/80-placements.rakutest |  77 ++++++++
 4 files changed, 588 insertions(+), 78 deletions(-)
 create mode 100644 xt/75-numbered.rakutest
 create mode 100644 xt/80-placements.rakutest

diff --git a/.gitignore b/.gitignore
index a6f976c..1a9965b 100644
--- a/.gitignore
+++ b/.gitignore
@@ -6,3 +6,4 @@ raku-pod-render.iml
 /.sass-cache/
 /problems/
 /check/
+/dump
diff --git a/lib/ProcessedPod.rakumod b/lib/ProcessedPod.rakumod
index 3825aed..2f0934f 100644
--- a/lib/ProcessedPod.rakumod
+++ b/lib/ProcessedPod.rakumod
@@ -40,6 +40,25 @@ grammar FC {
     # TODO: use "make" to pull inside-quotes value to meta
 }
 
+#| Class for setting numeration of headings and items
+class Numeration {
+    has Int @!counters is default(0);
+    method Str () { @!counters>>.Str.join('.') ~ '.' }
+    method inc ($level) {
+        @!counters[$level - 1]++;
+        @!counters.splice($level);
+        self
+    }
+    method reset () {
+        @!counters = Nil;
+        self
+    }
+    method set ( $level, $value ) {
+        @!counters[ $level - 1 ] = $value;
+        self
+    }
+}
+
 #| the name of the anchor at the top of a source file
 constant DEFAULT_TOP = '___top';
 
@@ -178,9 +197,14 @@ class ProcessedPod does SetupTemplates {
     # variables to manage Pod state, where rendering is dependent on local context
     #| for multilevel lists
     has @.itemlist;
+    #| item counter
+    has Numeration $.item-counter .= new;
     #| used to register state when processing a definition list
     has Bool $!in-defn-list = False;
 
+    #| for numbered headings
+    has Numeration $.header-counter .=new;
+
     #| the Config stack
     has @.config-stack ;
     #| contains the configuration for the outer pod/rakudoc block
@@ -597,15 +621,16 @@ class ProcessedPod does SetupTemplates {
         my $template = $node.config<template> // 'block-code';
         my $name-space = $node.config<name-space> // $template;
         my $data = $_ with %!plugin-data{ $name-space };
-
-        $retained-list
-            ~ $.completion($in-level, 'block-code',
-            %( :$contents,
+        my %params = %( :$contents,
                $node.config,
                "$name-space" => $data,
                :config(self.config),
-            ), :$defn
-        )
+        );
+        for %.config {
+            %params ,= .value.hash if .key eq "code"
+        }
+        $retained-list
+            ~ $.completion($in-level, 'block-code', %params, :$defn )
     }
     multi method handle(Pod::Block::Input $node, Int $in-level, Context $context = Preformatted, Bool :$defn = False,  --> Str) {
         # first completion is to flush a retained list before the contents of the block are processed
@@ -614,15 +639,16 @@ class ProcessedPod does SetupTemplates {
         my $template = $node.config<template> // 'input';
         my $name-space = $node.config<name-space> // $template;
         my $data = $_ with %!plugin-data{ $name-space };
-
+        my %params = %( :$contents,
+           $node.config,
+           "$name-space" => $data,
+           :config(self.config),
+        );
+        for %.config {
+            %params ,= .value.hash if .key eq "input"
+        }
         $retained-list
-            ~ $.completion($in-level, $template,
-            %( :$contents,
-               $node.config,
-               "$name-space" => $data,
-               :config(self.config),
-            ), :$defn
-        )
+            ~ $.completion($in-level, $template, %params, :$defn )
     }
     multi method handle(Pod::Block::Output $node, Int $in-level, Context $context = Preformatted, Bool :$defn = False,  --> Str) {
         # first completion is to flush a retained list before the contents of the block are processed
@@ -631,15 +657,16 @@ class ProcessedPod does SetupTemplates {
         my $template = $node.config<template> // 'output';
         my $name-space = $node.config<name-space> // $template;
         my $data = $_ with %!plugin-data{ $name-space };
-
+        my %params = %( :$contents,
+           $node.config,
+           "$name-space" => $data,
+           :config(self.config),
+        );
+        for %.config {
+            %params ,= .value.hash if .key eq "output"
+        }
         $retained-list
-            ~ $.completion($in-level, $template,
-            %( :$contents,
-               $node.config,
-               "$name-space" => $data,
-               :config(self.config),
-            ), :$defn
-        )
+            ~ $.completion($in-level, $template, %params, :$defn )
     }
 
     multi method handle(Pod::Block::Comment $node, Int $in-level, Context $context = None, Bool :$defn = False,  --> Str) {
@@ -671,19 +698,23 @@ class ProcessedPod does SetupTemplates {
         my $template = $node.config<template> // 'unknown-name';
         my $name-space = $node.config<name-space> // $template // $node.name.lc;
         my $data = $_ with %!plugin-data{ $name-space };
-
-        $.completion($in-level, 'zero', %(), :$defn )
-            ~ $.completion($in-level, $template, %(
-                :name($node.name),
-                "$name-space" => $data,
-                :$target,
-                :1level,
-                :contents([~] gather for $node.contents { take self.handle($_, $in-level, $context, :$defn ) }),
-                :top($.pod-file.top),
-                :config(self.config),
-                $node.config
-            ), :$defn
-        )
+        my $retained-list = $.completion($in-level, 'zero', %(), :$defn );
+        my $contents = [~] gather for $node.contents { take self.handle($_, $in-level, $context, :$defn ) };
+        my %params = %(
+            :name($node.name),
+            "$name-space" => $data,
+            :$target,
+            :1level,
+            :$contents,
+            :top($.pod-file.top),
+            :config(self.config),
+            $node.config
+        );
+        for %.config {
+            %params ,= .value.hash if .key eq $node.name
+        }
+        $retained-list
+            ~ $.completion($in-level, $template, %params, :$defn )
     }
 
     multi method handle(Pod::Block::Named $node where .name ~~ /:i ^ 'pod' | 'rakudoc' $/, Int $in-level,
@@ -848,51 +879,67 @@ class ProcessedPod does SetupTemplates {
         $contents ~= $.completion($in-level, 'zero', %(), :$defn );
         my $raw-contents = [~] gather for $node.contents { take self.handle($_, $in-level, Raw, :$defn ) }
         $raw-contents ~= $.completion($in-level, 'zero', %(), :$defn );
-        $unrendered-list ~ $.completion($in-level, $template, %(
-                :$contents,
-                $node.config,
-                :$target,
-                :$raw-contents,
-                $name-space => $data,
-                :config(self.config),
-            ), :$defn
-        )
+        my %params = %(
+            :$contents,
+            $node.config,
+            :$target,
+            :$raw-contents,
+            $name-space => $data,
+            :config(self.config),
+        );
+        for %.config {
+            %params ,= .value.hash if .key eq $node.name
+        }
+        $unrendered-list ~ $.completion($in-level, $template, %params, :$defn )
     }
 
     multi method handle(Pod::Block::Para $node, Int $in-level, Context $context where *== Preformatted, Bool :$defn = False, --> Str) {
-        $.completion($in-level, 'zero', %(), :$defn )
-            ~ $.completion($in-level, 'raw',
-            %( :contents([~] gather for $node.contents { take self.handle($_, $in-level, $context, :$defn) }),
-               $node.config, :config(self.config),)
-                , :$defn)
-
+        my $retained-list = $.completion($in-level, 'zero', %(), :$defn );
+        my $contents = [~] gather for $node.contents { take self.handle($_, $in-level, $context, :$defn) };
+        my %params = %( :$contents,
+           $node.config,
+           :config(self.config),
+        );
+        for %.config {
+            %params ,= .value.hash if .key eq "para"
+        }
+        $retained-list
+            ~ $.completion($in-level, 'raw', %params, :$defn )
     }
 
     multi method handle(Pod::Block::Para $node, Int $in-level, Context $context, Bool :$defn = False,  --> Str) {
         note "Defn flag is $defn and context is $context" if $.verbose;
-        $.completion($in-level, 'zero', %(), :$defn )
-            ~ $.completion($in-level, ($defn || $context !~~ None ) ?? 'raw' !! 'para' ,
-            %( :contents([~] gather for $node.contents { take self.handle($_, $in-level, $context) }),
-               $node.config, :config(self.config), )
-            , :$defn)
+        my $retained-list = $.completion($in-level, 'zero', %(), :$defn );
+        my $contents = [~] gather for $node.contents { take self.handle($_, $in-level, $context, :$defn) };
+        my %params = %( :$contents,
+           $node.config,
+           :config(self.config),
+        );
+        for %.config {
+            %params ,= .value.hash if .key eq "para"
+        }
+        $retained-list
+            ~ $.completion($in-level, ($defn || $context !~~ None ) ?? 'raw' !! 'para' , %params, :$defn )
     }
 
     multi method handle(Pod::Block::Table $node, Int $in-level, Context $context, Bool :$defn = False, --> Str) {
         my $template = $node.config<template> // 'table';
         my @headers = gather for $node.headers { take self.handle($_, $in-level, $context) };
-        $.completion($in-level, 'zero', %(), :$defn)
-            ~ $.completion($in-level, $template, %(
-                :caption($node.caption ?? $.handle($node.caption, $in-level, $context) !! ''),
-                :headers(+@headers ?? %( :cells(@headers)) !! Nil),
-                :rows([gather for $node.contents -> @r {
-                    take %( :cells([gather for @r { take $.handle($_, $in-level, $context, :$defn) }]))
-                }]),
-                $node.config,
-                :config(self.config),
-                :$context,
-            ),
-            :$defn
-        )
+        my $retained-list = $.completion($in-level, 'zero', %(), :$defn);
+        my %params = %(
+            :caption($node.caption ?? $.handle($node.caption, $in-level, $context) !! ''),
+            :headers(+@headers ?? %( :cells(@headers)) !! Nil),
+            :rows([gather for $node.contents -> @r {
+                take %( :cells([gather for @r { take $.handle($_, $in-level, $context, :$defn) }]))
+            }]),
+            $node.config,
+            :config(self.config),
+            :$context,
+        );
+        for %.config {
+            %params ,= .value.hash if .key eq "table"
+        }
+        $retained-list ~ $.completion($in-level, $template, %params, :$defn )
     }
     # RakuDoc makes row/column directives, but POD6 thinks they are blocks, so metadata are in contents
     sub grid-directive-config( $instruction --> Hash ) {
@@ -949,6 +996,7 @@ class ProcessedPod does SetupTemplates {
         my $template = %table-config<template> // 'table';
         my $name-space = %table-config<name-space> // $template;
         my $data = $_ with %!plugin-data{ $name-space };
+        my $retained-list = $.completion($in-level, 'zero', %(), :$defn );
 
         # grid traversing algorithm due to Damian Conway
         # Initially empty grid...
@@ -1059,15 +1107,18 @@ class ProcessedPod does SetupTemplates {
             # Update previous action...
             $prev-was-cell = $grid-instruction.name eq 'cell';
         };
-        $.completion($in-level, $template, %(
+        my %params = %(
             $name-space => $data,
             :config(self.config),
             :@grid,
             :procedural,
             :$target,
             :$caption,
-            ), :$defn
-        )
+        );
+        for %.config {
+            %params ,= .value.hash if .key eq "table"
+        }
+        $retained-list ~ $.completion($in-level, 'raw', %params, :$defn )
     }
 
     multi method handle(Pod::Defn $node, Int $in-level, Context $context --> Str) {
@@ -1095,7 +1146,7 @@ class ProcessedPod does SetupTemplates {
         my $target = $.register-toc(:$level, :text( recurse-until-str($node).join.trim ), :unique);
         # must register toc before processing content!!
         my $text = trim([~] gather for $node.contents { take $.handle($_, $in-level, Heading, :$defn) });
-        $retained-list ~ $.completion($in-level, $template, {
+        my %params = (
             :$level,
             :$text,
             :$target,
@@ -1104,8 +1155,12 @@ class ProcessedPod does SetupTemplates {
             $node.config,
             :config(self.config),
             :$context,
-            }, :$defn
-        )
+            :numeration( $.header-counter.inc( $level ).Str ),
+            );
+        for %.config {
+            %params ,= .value.hash if .key eq "head$level"
+        }
+        $retained-list ~ $.completion($in-level, $template, %params, :$defn )
     }
 
     multi method handle(Pod::Item $node, Int $in-level is copy, Context $context, Bool :$defn = False, --> Str) {
@@ -1115,12 +1170,15 @@ class ProcessedPod does SetupTemplates {
             $.itemlist[$in-level] ~= $.rendition('list', %( :items($.itemlist.pop), :config(self.config),))
         }
         while $level >= $in-level {
-            $.itemlist[$in-level] = [] unless $.itemlist[$in-level]:exists;
+            unless $.itemlist[$in-level]:exists {
+                $.itemlist[$in-level] = []
+            }
             ++$in-level
         }
         $.itemlist[$in-level - 1].push: $.rendition('item',
                 %( :contents([~] gather for $node.contents { take self.handle($_, $in-level, $context) }),
-                   $node.config, :config(self.config), :$context, )
+                   $node.config,
+                   :config(self.config), :$context, )
                 );
         return ''
         # explicitly return an empty string because callers expecting a Str
@@ -1279,8 +1337,8 @@ class ProcessedPod does SetupTemplates {
                 my $level;
                 $.pod-file.raw-metadata
                         .grep({ .<name> ~~ $uri })
-                        .map({ 
-                            $contents ~= .<value> ; 
+                        .map({
+                            $contents ~= .<value> ;
                             $caption = .<caption> without $caption;
                             $level = .<level> without $level;
                         });
diff --git a/xt/75-numbered.rakutest b/xt/75-numbered.rakutest
new file mode 100644
index 0000000..31557ba
--- /dev/null
+++ b/xt/75-numbered.rakutest
@@ -0,0 +1,374 @@
+use v6.d;
+use Test;
+
+use ProcessedPod;
+
+# A helper class for RakuClosureTemplates
+multi sub gen-closure-template (Str $tag) is export {
+    my $start = '<' ~ $tag ~ '>';
+    my $end = '</' ~ $tag ~ '>';
+    return sub (%prm, %tml? --> Str) {
+        $start ~ (%prm<contents> // %prm<text> // '') ~ $end;
+    }
+}
+plan *;
+
+my $processor = ProcessedPod.new;
+my $pv = 0;
+my $rv;
+
+# test numeration before templates set up.
+is $processor.header-counter.inc(1).Str, '1.', 'simple inc';
+is $processor.header-counter.inc(2).Str, '1.1.', '2-level inc';
+is $processor.header-counter.inc(4).Str, '1.1.0.1.', '4-level inc';
+is $processor.header-counter.inc(2).Str, '1.2.', '2-level inc, resets other levels.';
+is $processor.header-counter.inc(4).Str, '1.2.0.1.', '4-level inc, after reset';
+$processor.header-counter.reset;
+is $processor.header-counter.inc(2).Str, '0.1.', 'reset then 2-level inc';
+$processor.header-counter.set(4,3);
+is $processor.header-counter.Str, '0.1.0.3.', 'set works on 4-level';
+
+
+use RenderPod::Templating;
+my @templates = SetupTemplates.new.required;
+
+my %templates = @templates Z=> @templates.map({ gen-closure-template($_) });
+%templates ,= %(
+    escaped => sub ($s) {
+        $s
+    },
+    para => sub (%prm, %) {
+        %prm<contents> ~ "\n"
+    },
+    heading => sub (%prm, %) {
+        qq:to/HEAD/;
+            { %prm<numbered> ?? %prm<numeration> !! '' } { %prm<text> }
+            HEAD
+    },
+    item => sub (%prm, %) {
+        qq:to/ITEM/;
+            <li>{ %prm<contents> }</li>
+            ITEM
+    },
+    'list' => sub ( %prm, %tml ) {
+        qq:to/LIST/;
+        <ol type="{ %prm<html-ol> }">
+        { %prm<items>.join }
+        </ol>
+        LIST
+    },
+);
+$processor.templates(%templates);
+
+=begin rakudoc
+=for head1 :numbered
+The Problem
+
+=for head1 :numbered
+The Solution
+
+    =for head2 :numbered
+    Analysis
+
+        =for head3
+        Overview
+
+        =for head3
+        Details
+
+    =for head2 :numbered
+    Design
+
+=for head1 :numbered
+The Implementation
+
+=end rakudoc
+$rv = $processor.render-block( $=pod[$pv++] );
+like $rv,
+    /
+    '1. The Problem'
+    \D+
+    '2. The Solution'
+    \D+
+    '2.1. Analysis'
+    \D+
+    'Overview'
+    \D+
+    'Details'
+    \D+
+    '2.2. Design'
+    \D+
+    '3. The Implementation'
+    /
+    , 'Numbered titles as per RakuDoc-2';
+
+=begin rakudoc
+=config head1 :numbered
+=config head2 :numbered
+=config head3 :!numbered
+
+=head1 The Problem
+=head1 The Solution
+=head2   Analysis
+=head3     Overview
+=head3     Details
+=head2   Design
+=head1 The Implementation
+=end rakudoc
+
+# reset header counter to 0
+$processor.header-counter.reset;
+$rv = $processor.render-block( $=pod[$pv++] );
+like $rv,
+    /
+    '1. The Problem'
+    \D+
+    '2. The Solution'
+    \D+
+    '2.1. Analysis'
+    \D+
+    'Overview'
+    \D+
+    'Details'
+    \D+
+    '2.2. Design'
+    \D+
+    '3. The Implementation'
+    /
+    , 'Config with numbered titles as per RakuDoc-2';
+=begin rakudoc
+=head1 # The Problem
+=head1 # The Solution
+=head2   # Analysis
+=head3       Overview
+=head3       Details
+=head2   # Design
+=head1 # The Implementation
+=end rakudoc
+$processor.header-counter.reset;
+$rv = $processor.render-block( $=pod[$pv++] );
+like $rv,
+    /
+    '1. The Problem'
+    \D+?
+    '2. The Solution'
+    \D+?
+    '2.1. Analysis'
+    \D+?
+    'Overview'
+    \D+?
+    'Details'
+    \D+?
+    '2.2. Design'
+    \D+?
+    '3. The Implementation'
+    /
+    , '# Numbered titles as per RakuDoc-2';
+=begin rakudoc
+=head6 # The Rescue of the Kobayashi Maru
+=end rakudoc
+$processor.header-counter.reset;
+$processor.header-counter
+        .set(1,2)
+        .set(2,3)
+        .set(3,8)
+        .set(4,6)
+        .set(5,1)
+        .set(6,8);
+$rv = $processor.render-block( $=pod[$pv++] );
+like $rv,
+    /
+    '2.3.8.6.1.9. The Rescue of the Kobayashi Maru'
+    /
+    , 'Arbitrary numbered title as per RakuDoc-2';
+
+diag 'numbered items';
+=begin rakudoc
+     =for item1 :numbered
+     Visito
+
+     =for item2 :numbered
+     Veni
+
+     =for item2 :numbered
+     Vidi
+
+     =for item2 :numbered
+     Vici
+=end rakudoc
+$rv = $processor.render-block( $=pod[$pv++] );
+like $rv,
+    /
+    '1. Visito'
+    .+?
+    '1.1. Veni'
+    .+?
+    '1.2. Vidi'
+    .+?
+    '1.3. Vici'
+    /
+    , 'Numbered item list as per RakuDoc-2';
+
+=begin rakudoc
+     =item1  # Visito
+     =item2     # Veni
+     =item2     # Vidi
+     =item2     # Vici
+=end rakudoc
+
+$rv = $processor.render-block( $=pod[$pv++] );
+like $rv,
+    /
+    '1. Visito'
+    .+?
+    '1.1. Veni'
+    .+?
+    '1.2. Vidi'
+    .+?
+    '1.3. Vici'
+    /
+    , '# Numbered item list as per RakuDoc-2';
+
+=begin rakudoc
+    =item V<#> introduces a comment
+=end rakudoc
+
+$rv = $processor.render-block( $=pod[$pv++] );
+like $rv,
+    /
+    '# introduces a comment'
+    /
+    , 'Ornithorpe item list as per RakuDoc-2';
+
+#=begin rakudoc
+#    =for item :!numbered
+#    # introduces a comment
+#=end rakudoc
+#$rv = $processor.render-block( $=pod[$pv++] );
+#like $rv,
+#    /
+#    '# introduces a comment'
+#    /
+#    , 'Ornithorpe item list as per RakuDoc-2';
+
+=begin rakudoc
+The options are:
+
+=item1 # Liberty
+=item1 # Death
+=item1 # Beer
+
+The tools are:
+
+=item1 # Revolution
+=item1 # Deep-fried peanut butter sandwich
+=item1 # Keg
+=end rakudoc
+
+$rv = $processor.render-block( $=pod[$pv++] );
+like $rv,
+    /
+    'The options are:'
+    .+?
+    '1. Liberty'
+    .+?
+    '2. Death'
+    .+?
+    '3. Beer'
+    .+?
+    'The tools are:'
+    .+?
+    '1. Revolution'
+    .+?
+    '2. Deep-fried peanut butter sandwich'
+    .+?
+    '3. Keg'
+    /
+    , 'Hash numbered item list as per RakuDoc-2';
+
+#=begin rakudoc
+#     =for item1
+#     # Retreat to remote Himalayan monastery
+#
+#     =for item1
+#     # Learn the hidden mysteries of space and time
+#
+#     I<????>
+#
+#     =for item1 :continued
+#     # Prophet!
+#=end rakudoc
+#$rv = $processor.render-block( $=pod[$pv++] );
+#like $rv,
+#    /
+#    '1. Retreat to remote Himalayan monastery'
+#    .+?
+#    '2. Learn the hidden mysteries of space and time'
+#    \D+?
+#    '????'
+#    .+?
+#    '3. Prophet!'
+#    /
+#    , 'continued numbered item list as per RakuDoc-2';
+
+=begin rakudoc
+=config item1 :numbered
+=config item2 :numbered
+=item1  Visito
+=item2  Veni
+=item2  Vidi
+=item2  Vici
+=end rakudoc
+
+$rv = $processor.render-block( $=pod[$pv++] );
+like $rv,
+    /
+    '1. Visito'
+    .+?
+    '1.1. Veni'
+    .+?
+    '1.2. Vidi'
+    .+?
+    '1.3. Vici'
+    /
+    , 'Config numbered item list';
+
+
+=begin rakudoc
+=config item1 :numbered :html-ol<L>
+=config item2 :numbered :html-ol<i>
+=item1  Visito
+=item2  Veni
+=item2  Vidi
+=item2  Vici
+=item1  Caesar said
+=item2  I came
+=item2  I saw
+=item2  I conquered
+=item2  which he did
+=end rakudoc
+
+$rv = $processor.render-block( $=pod[$pv++] );
+like $rv,
+    /
+    'A. Visito'
+    .+?
+    'A.i. Veni'
+    .+?
+    'A.ii. Vidi'
+    .+?
+    'A.iii. Vici'
+    .+?
+    'B. Caesar said'
+    .+?
+    'B.i. I came'
+    .+?
+    'B.ii. I saw'
+    .+?
+    'B.iii. I conquered'
+    .+?
+    'B.iv. which he did'
+    /
+    , 'Config numbered item list with html-ol enhancement';
+
+done-testing;
\ No newline at end of file
diff --git a/xt/80-placements.rakutest b/xt/80-placements.rakutest
new file mode 100644
index 0000000..df87d88
--- /dev/null
+++ b/xt/80-placements.rakutest
@@ -0,0 +1,77 @@
+use v6.d;
+use Test;
+
+use ProcessedPod;
+
+# A helper class for RakuClosureTemplates
+multi sub gen-closure-template (Str $tag) is export {
+    my $start = '<' ~ $tag ~ '>';
+    my $end = '</' ~ $tag ~ '>';
+    return sub (%prm, %tml? --> Str) {
+        $start ~ (%prm<contents> // %prm<text> // '') ~ $end;
+    }
+}
+plan *;
+
+my $processor = ProcessedPod.new;
+my $pv = 0;
+my $rv;
+
+use RenderPod::Templating;
+my @templates = SetupTemplates.new.required;
+
+my %templates = @templates Z=> @templates.map({ gen-closure-template($_) });
+%templates ,= %(
+    escaped => sub ($s) {
+        $s
+    },
+    para => sub (%prm, %) {
+        %prm<contents> ~ "\n"
+    },
+    format-p => sub (%prm, %) {
+        qq:to/HEAD/;
+            { %prm<numbered> ?? %prm<numeration> !! '' } { %prm<text> }
+            HEAD
+    },
+);
+$processor.templates(%templates);
+
+=begin rakudoc
+
+=head1 License
+
+P<https://github.com/Raku/doc/blob/main/LICENSE>
+
+=end rakudoc
+$rv = $processor.render-block( $=pod[$pv++] );
+like $rv,
+    /
+    '<body' .+ 'Artistic License 2.0' .+ '</body'
+    /,'Seems to have got Artistic License';
+
+=begin rakudoc
+
+=head1 Readme text
+P<file:README.md>
+
+=end rakudoc
+
+$rv = $processor.render-block( $=pod[$pv++] );
+like $rv,
+    /
+    '# Generic Pod Renderer'
+    /,'Seems to have got file contents';
+
+=begin rakudoc
+
+P<toc:>
+
+=end rakudoc
+
+$rv = $processor.render-block( $=pod[$pn++] );
+like $rv, /
+    'Table of Contents not rendered until document is complete'
+    /, 'Premature stringification of ToC';
+
+
+done-testing;
\ No newline at end of file