-
Notifications
You must be signed in to change notification settings - Fork 13
/
ssh-tunnels.el
555 lines (482 loc) · 20.2 KB
/
ssh-tunnels.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
;;; ssh-tunnels.el --- Manage SSH tunnels
;; Author: death <github.com/death>
;; Version: 1.0
;; Package-Requires: ((cl-lib "0.5") (emacs "24"))
;; Keywords: tools, convenience
;; URL: http://github.com/death/ssh-tunnels
;; This file is not part of GNU Emacs.
;; Copyright (c) 2015 death
;; Permission is hereby granted, free of charge, to any person
;; obtaining a copy of this software and associated documentation
;; files (the "Software"), to deal in the Software without
;; restriction, including without limitation the rights to use, copy,
;; modify, merge, publish, distribute, sublicense, and/or sell copies
;; of the Software, and to permit persons to whom the Software is
;; furnished to do so, subject to the following conditions:
;; The above copyright notice and this permission notice shall be
;; included in all copies or substantial portions of the Software.
;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
;; NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS
;; BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
;; ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
;; CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
;; SOFTWARE.
;;; Commentary:
;; This package lets you run and kill SSH tunnels. To use it:
;;
;; - Set the variable `ssh-tunnels-configurations', e.g.:
;;
;; (setq ssh-tunnels-configurations
;; '((:name "my local tunnel"
;; :local-port 1234
;; :remote-port 3306
;; :login "me@host")
;; (:name "my remote tunnel"
;; :type "-R"
;; :local-port 1234
;; :remote-port 3306
;; :login "me@host")
;; (:name "my local socket tunnel"
;; :type "-L"
;; :local-socket "/tmp/socket"
;; :remote-socket "/tmp/socket"
;; :login "me@host")))
;;
;; - Type M-x ssh-tunnels RET
;;
;; - You should see the list of tunnels; running tunnels will have 'R'
;; in their state column
;;
;; - To run the tunnel at the current line, type r
;;
;; - To kill a running tunnel, type k
;;
;; - You may want to temporarily change a tunnel's local port. To do
;; that you may provide a prefix argument to the run command, for
;; example by typing C-u 1235 r
;;; Code:
(require 'cl-lib)
(require 'netrc)
(require 'tabulated-list)
(defgroup ssh-tunnels nil
"View and manipulate SSH tunnels."
:group 'tools
:group 'convenience)
(defcustom ssh-tunnels-use-header-line t
"If non-nil, use the header line to display ssh-tunnels column titles."
:type 'boolean
:group 'ssh-tunnels)
(defface ssh-tunnels-name
'((t (:weight bold)))
"Face for ssh tunnel names in the ssh tunnels buffer."
:group 'ssh-tunnels)
(defcustom ssh-tunnels-name-width 20
"Width of tunnel name column in the ssh tunnels buffer."
:type 'number
:group 'ssh-tunnels)
(defcustom ssh-tunnels-local-port-width 7
"Width of tunnel local port column in the ssh tunnels buffer."
:type 'number
:group 'ssh-tunnels)
(defcustom ssh-tunnels-host-width 50
"Width of tunnel host column in the ssh tunnels buffer."
:type 'number
:group 'ssh-tunnels)
(defcustom ssh-tunnels-remote-port-width 7
"Width of tunnel remote port column in the ssh tunnels buffer."
:type 'number
:group 'ssh-tunnels)
(defcustom ssh-tunnels-login-width 50
"Width of tunnel login column in the ssh tunnels buffer."
:type 'number
:group 'ssh-tunnels)
(defcustom ssh-tunnels-program "ssh"
"The name of the SSH program."
:type 'string
:group 'ssh-tunnels)
(defcustom ssh-tunnels-configurations '()
"A list of SSH tunnel configurations. Each element is a plist
with the following properties:
:name - The name of the tunnel.
:type - Tunnel type; defaults to \"-L\" (Local).
May also be \"-R\" or \"-D\" for Remote and Dynamic tunnels.
If set to \"SH\", no port forwarding will be attempted and your ssh
client is responsible for tunnelling (e.g. with ~/.ssh/config), in
this case `:login' must match your ~/.ssh/config entry and `:host',
`:local-port', `:remote-port', `:local-socket', `:remote-socket'
are ignored.
:login - The SSH login to use.
:host - The tunneling host; defaults to \"localhost\".
:local-port - The tunnel's local port; defaults
to the value of `:remote-port'.
:remote-port - The tunnel's remote port; defaults
to the value of `:local-port'.
For tunneling sockets, use the properties below, instead of `:local-port'
and/or `:remote-port'.
:local-socket - The tunnel's local socket; defaults
to the value of `:remote-socket'.
:remote-socket - The tunnel's remote socket; defaults
to the value of `:local-socket'.
:group - The tunnel's group (a string); defaults to none (`nil').
Tunnels belonging to the same group may be started or killed
together (e.g., by `ssh-tunnels-run-group').
"
:type 'sexp
:group 'ssh-tunnels)
(defcustom ssh-tunnels-temp-directory "/tmp/"
"The directory where SSH control socket files will reside."
:type 'string
:group 'ssh-tunnels)
(defvar ssh-tunnels--state-table
(make-hash-table :test 'equal)
"A table to keep tunnel-related state.
Note that we'll lose this state if the user exits Emacs (rms
forbid...), or it may become irrelevant if
`ssh-tunnels-configurations' changes.
The table is keyed by tunnel names. The state is the local port
or socket associated with the tunnel.")
(defvar ssh-tunnels-mode-map
(let ((map (make-sparse-keymap)))
(set-keymap-parent map tabulated-list-mode-map)
(define-key map "q" 'quit-window)
(define-key map "g" 'ssh-tunnels-refresh)
(define-key map "r" 'ssh-tunnels-run)
(define-key map "k" 'ssh-tunnels-kill)
(define-key map "R" 'ssh-tunnels-rerun)
map))
(define-derived-mode ssh-tunnels-mode tabulated-list-mode "SSH tunnels"
"Major mode for managing SSH tunnels."
(add-hook 'tabulated-list-revert-hook 'ssh-tunnels-refresh nil t))
;;;###autoload
(defun ssh-tunnels ()
"View and manipulate SSH tunnels."
(interactive)
(switch-to-buffer (ssh-tunnels--noselect)))
(defun ssh-tunnels--noselect ()
(let ((buffer (get-buffer-create "*SSH tunnels*")))
(with-current-buffer buffer
(ssh-tunnels-mode)
(ssh-tunnels-refresh))
buffer))
(defun ssh-tunnels-refresh ()
(interactive)
(let ((name-width ssh-tunnels-name-width)
(local-port-width ssh-tunnels-local-port-width)
(host-width ssh-tunnels-host-width)
(remote-port-width ssh-tunnels-remote-port-width)
(login-width ssh-tunnels-login-width))
(setq tabulated-list-format
(vector `("S" 1 t)
`("Name" ,name-width t)
`("Type" 4 t)
`("LPort" ,local-port-width ssh-tunnels--lport> :right-align t)
`("Host" ,host-width t)
`("RPort" ,remote-port-width ssh-tunnels--rport> :right-align t)
`("Login" ,login-width t))))
(setq tabulated-list-use-header-line ssh-tunnels-use-header-line)
(let ((entries '()))
(dolist (tunnel ssh-tunnels-configurations)
(let* ((name (ssh-tunnels--property tunnel :name))
(tunnel-type (ssh-tunnels--property tunnel :type))
(local-port (ssh-tunnels--property tunnel :local-port))
(remote-port (ssh-tunnels--property tunnel :remote-port))
(local-socket (ssh-tunnels--property tunnel :local-socket))
(remote-socket (ssh-tunnels--property tunnel :remote-socket))
(host (ssh-tunnels--property tunnel :host))
(login (ssh-tunnels--property tunnel :login)))
(ssh-tunnels--validate tunnel)
(push (list tunnel
(vector (if (ssh-tunnels--check tunnel) "R" " ")
(ssh-tunnels--pretty-name name)
tunnel-type
(if (numberp local-port)
(number-to-string local-port)
local-socket)
host
(if (numberp remote-port)
(number-to-string remote-port)
remote-socket)
login))
entries)))
(setq tabulated-list-entries (nreverse entries)))
(tabulated-list-init-header)
(tabulated-list-print t))
(defun ssh-tunnels--lport> (entry1 entry2)
(> (string-to-number (aref (cadr entry1) 3))
(string-to-number (aref (cadr entry2) 3))))
(defun ssh-tunnels--rport> (entry1 entry2)
(> (string-to-number (aref (cadr entry1) 5))
(string-to-number (aref (cadr entry2) 5))))
(defun ssh-tunnels--pretty-name (name)
(propertize name
'font-lock-face 'ssh-tunnels-name
'mouse-face 'highlight))
(defun ssh-tunnels--tunnel (&optional error-if-does-not-exist)
(let ((tunnel (tabulated-list-get-id)))
(cond ((null tunnel)
(if error-if-does-not-exist
(error "No tunnel on this line")))
(t tunnel))))
(defun ssh-tunnels-run (&optional arg)
(interactive "P")
(let ((tunnel (ssh-tunnels--tunnel t)))
(when (numberp arg)
;; Use an ad-hoc local port instead of the local port or socket
;; specified in configuration.
(setf tunnel (cl-copy-list tunnel))
(cl-remf tunnel :local-port)
(cl-remf tunnel :local-socket)
(setf tunnel (cl-list* :local-port arg tunnel)))
(ssh-tunnels--validate tunnel)
(when (not (ssh-tunnels--check tunnel))
(message "Tunneling...")
(ssh-tunnels--run tunnel)
(let ((name (ssh-tunnels--property tunnel :name))
(local-port (ssh-tunnels--property tunnel :local-port))
(local-socket (ssh-tunnels--property tunnel :local-socket)))
(if (numberp local-port)
(message "Tunnel '%s' on port %d" name local-port)
(message "Tunnel '%s' on socket '%s'" name local-socket)))))
(forward-line)
(ssh-tunnels-refresh))
(defun ssh-tunnels-kill ()
(interactive)
(let ((tunnel (ssh-tunnels--tunnel t)))
(when (ssh-tunnels--check tunnel)
(ssh-tunnels--kill tunnel)
(message "Tunnel '%s' killed" (ssh-tunnels--property tunnel :name))))
(forward-line)
(ssh-tunnels-refresh))
(defun ssh-tunnels-rerun (&optional arg)
(interactive "P")
(ssh-tunnels-kill)
(forward-line -1)
(ssh-tunnels-run arg))
(defun ssh-tunnels--property (tunnel key)
(cond ((eq key :host)
(or (cl-getf tunnel :host) "localhost"))
((eq key :type)
(or (cl-getf tunnel :type) "-L"))
((eq key :local-port)
(let ((state (gethash (cl-getf tunnel :name) ssh-tunnels--state-table)))
(if (numberp state)
state
(or (cl-getf tunnel :local-port)
(and (null (cl-getf tunnel :local-socket))
(cl-getf tunnel :remote-port))))))
((eq key :remote-port)
(and (null (cl-getf tunnel :remote-socket))
(or (cl-getf tunnel :remote-port)
(cl-getf tunnel :local-port))))
((eq key :local-socket)
(let ((state (gethash (cl-getf tunnel :name) ssh-tunnels--state-table)))
(if (stringp state)
state
(or (cl-getf tunnel :local-socket)
(and (null (cl-getf tunnel :local-port))
(cl-getf tunnel :remote-socket))))))
((eq key :remote-socket)
(and (null (cl-getf tunnel :remote-port))
(or (cl-getf tunnel :remote-socket)
(cl-getf tunnel :local-socket))))
(t
(cl-getf tunnel key))))
(defun ssh-tunnels--validate (tunnel)
;; Note that we don't use ssh-tunnels--property to check for
;; mutually exclusive options, to avoid its default value behavior.
(when (and (cl-getf tunnel :local-port)
(cl-getf tunnel :local-socket))
(error "Tunnel '%s' has both a `:local-port' and a `:local-socket'"
(ssh-tunnels--property tunnel :name)))
(when (and (cl-getf tunnel :remote-port)
(cl-getf tunnel :remote-socket))
(error "Tunnel '%s' has both a ':remote-port' and a ':remote-socket'"
(ssh-tunnels--property tunnel :name))))
(defun ssh-tunnels--command (tunnel command)
(let* ((name (ssh-tunnels--property tunnel :name))
(tunnel-type (ssh-tunnels--property tunnel :type))
(login (ssh-tunnels--property tunnel :login))
(args
(cond ((eq command :run)
(append (list "-M" "-f" "-N" "-T")
(if (string= tunnel-type "SH")
'()
(list tunnel-type
(ssh-tunnels--forward-definition tunnel)))))
((eq command :kill)
(list "-O" "exit"))
((eq command :check)
(list "-O" "check"))
(t (error "Unknown ssh-tunnels command '%s'" command))))
(default-directory ssh-tunnels-temp-directory))
(with-temp-buffer
(let ((exit-status
(apply 'call-process ssh-tunnels-program nil t nil
"-S" (shell-quote-argument name)
(append args (list login)))))
(when (and (eq command :run)
(not (eql 0 exit-status)))
(if (numberp exit-status)
(error "Tunnel '%s' could not be created: '%s' (exit status %d)"
name
(buffer-substring-no-properties (point-min) (point-max))
exit-status)
(error "Tunnel '%s' could not be created: process exited with signal '%s'"
name
exit-status)))
exit-status))))
(defun ssh-tunnels--run (tunnel)
(remhash (ssh-tunnels--property tunnel :name)
ssh-tunnels--state-table)
(ssh-tunnels--command tunnel :run)
(puthash (ssh-tunnels--property tunnel :name)
(or (ssh-tunnels--property tunnel :local-port)
(ssh-tunnels--property tunnel :local-socket))
ssh-tunnels--state-table))
(defun ssh-tunnels--kill (tunnel)
(ssh-tunnels--command tunnel :kill)
(remhash (ssh-tunnels--property tunnel :name)
ssh-tunnels--state-table))
(defun ssh-tunnels--check (tunnel)
(eql 0 (ssh-tunnels--command tunnel :check)))
(defun ssh-tunnels--toggle-state (tunnel)
(if (ssh-tunnels--check tunnel)
(ssh-tunnels--kill tunnel)
(ssh-tunnels--run tunnel)))
(defun ssh-tunnels--forward-definition (tunnel)
(let* ((name (ssh-tunnels--property tunnel :name))
(tunnel-type (ssh-tunnels--property tunnel :type))
(local-port (ssh-tunnels--property tunnel :local-port))
(remote-port (ssh-tunnels--property tunnel :remote-port))
(local-socket (ssh-tunnels--property tunnel :local-socket))
(remote-socket (ssh-tunnels--property tunnel :remote-socket))
(host (ssh-tunnels--property tunnel :host))
(host
(if (string-match-p (regexp-quote ":") host)
(format "[%s]" host)
host)))
(cond ((string= tunnel-type "-D")
(unless (numberp local-port)
(error "No local port specified for tunnel '%s'" name))
(format "%s:%s" host local-port))
((string= tunnel-type "-R")
(cond
((and remote-port local-socket)
(format "%s:%s:%s" host remote-port local-socket))
((and remote-socket local-socket)
(format "%s:%s" remote-socket local-socket))
(t (format "%s:%s:%s"
(or remote-port remote-socket)
host
(or local-port local-socket)))))
(t
;; Default Local port forwarding
(cond
((and local-port remote-socket)
(format "%s:%s:%s" host local-port remote-socket))
((and local-socket remote-socket)
(format "%s:%s" local-socket remote-socket))
((and local-socket remote-port)
(format "%s:%s:%s" local-socket host remote-port))
(t (format "%s:%s:%s"
(or local-port local-socket)
host
(or remote-port remote-socket))))))))
;;; completing-read frontend
(defun ssh-tunnels--list-tunnel-names ()
"Return a list of SSH tunnel names."
(cl-loop for tunnel in ssh-tunnels-configurations
collect (ssh-tunnels--property tunnel :name)))
(defun ssh-tunnels--read-tunnel-name ()
"Read an SSH tunnel name from the minibuffer."
(completing-read "Tunnel: " (ssh-tunnels--list-tunnel-names) nil t))
(defun ssh-tunnels--get-tunnel-by-name (tunnel-name)
"Return an SSH tunnel with the supplied name, or NIL if none is
found."
(cl-find tunnel-name ssh-tunnels-configurations
:test #'string=
:key (lambda (tunnel)
(ssh-tunnels--property tunnel :name))))
(defun ssh-tunnels-run-tunnel (tunnel-name)
"Start a configured SSH tunnel."
(interactive (list (ssh-tunnels--read-tunnel-name)))
(let ((tunnel (ssh-tunnels--get-tunnel-by-name tunnel-name)))
(when tunnel
(ssh-tunnels--run tunnel))))
(defun ssh-tunnels-kill-tunnel (tunnel-name)
"Kill a running SSH tunnel."
(interactive (list (ssh-tunnels--read-tunnel-name)))
(let ((tunnel (ssh-tunnels--get-tunnel-by-name tunnel-name)))
(when tunnel
(ssh-tunnels--kill tunnel))))
(defun ssh-tunnels--list-groups ()
"Return a list of SSH tunnel groups."
(remove nil
(cl-remove-duplicates
(mapcar (lambda (tunnel)
(ssh-tunnels--property tunnel :group))
ssh-tunnels-configurations)
:test #'string=)))
(defun ssh-tunnels--read-group ()
"Read an SSH tunnel group from the minibuffer."
(completing-read "Group: " (ssh-tunnels--list-groups) nil t))
(defun ssh-tunnels--get-tunnels-by-group (group)
"Return a list of SSH tunnels matching `group'."
(cl-loop for tunnel in ssh-tunnels-configurations
when (string= (ssh-tunnels--property tunnel :group) group)
collect tunnel))
(defun ssh-tunnels-run-group (group)
"Start configured SSH tunnels by given group."
(interactive (list (ssh-tunnels--read-group)))
(dolist (tunnel (ssh-tunnels--get-tunnels-by-group group))
(ssh-tunnels--run tunnel)))
(defun ssh-tunnels-kill-group (group)
"Kill configured SSH tunnels by given group."
(interactive (list (ssh-tunnels--read-group)))
(dolist (tunnel (ssh-tunnels--get-tunnels-by-group group))
(ssh-tunnels--kill tunnel)))
(defun ssh-tunnels-kill-all ()
"Kill all SSH configured tunnels."
(interactive)
(dolist (tunnel ssh-tunnels-configurations)
(ssh-tunnels--kill tunnel)))
;;; auto-ssh-tunnels mode
(defun ssh-tunnels--lookup (host service)
"Return an SSH tunnel that matches the supplied HOST and
SERVICE, or NIL if there is no match."
;; According to OPEN-NETWORK-STREAM documentation, SERVICE may be a
;; service name, or an integer, or an integer string. If it is an
;; integer string, we convert it to an integer here.
(when (and (stringp service)
(cl-some #'cl-digit-char-p service)
(cl-every #'cl-digit-char-p service))
(setq service (string-to-number service)))
(cl-find-if (lambda (tunnel)
(and (not (string= "SH" (ssh-tunnels--property tunnel :type)))
(string= host (ssh-tunnels--property tunnel :host))
(let ((tunnel-lport (ssh-tunnels--property tunnel :local-port)))
(and (numberp tunnel-lport)
(if (stringp service)
(netrc-port-equal service tunnel-lport)
(= service tunnel-lport))))))
ssh-tunnels-configurations))
(defun open-network-stream@run-ssh-tunnel (name buffer host service &rest parameters)
"Start SSH tunnel, if needed, before connecting to HOST.
Check whether `ssh-tunnels-configurations' has a tunnel matching
the host and service and, if so, make sure that the tunnel is
running."
(let ((tunnel (ssh-tunnels--lookup host service)))
(when (and tunnel (not (ssh-tunnels--check tunnel)))
(message "Starting tunnel '%s'..." (ssh-tunnels--property tunnel :name))
(ssh-tunnels--run tunnel))))
(define-minor-mode auto-ssh-tunnels-mode "Automatically start SSH tunnels"
:global t
:group 'ssh-tunnels
(if auto-ssh-tunnels-mode
(advice-add 'open-network-stream :before
#'open-network-stream@run-ssh-tunnel)
(advice-remove 'open-network-stream #'open-network-stream@run-ssh-tunnel)))
(provide 'ssh-tunnels)
;;; ssh-tunnels.el ends here